INTERFACE-Programmierung

Schraubt man nun die Schnittstellenerweiterung auf, so sieht man sofort zwei große Chips:
• Z80 DART Dies ist ein Chip, der zwei UARTs (serielle Schnittstellen) beinhaltet.
• 8253 Ein Timer Chip mit drei unabhängigen Timer Kanälen.

• ¹/2 Z80 DART UART mit Hardware Handshake Signalen
• ²/3 8253 Zwei Timer für Sender und Empfänger Raten

• 1 74LS373 Acht Bit Latch für die Daten
• ¹/2 Z80 DART II für Strobe und BUSY
• ¹/3 8253 Für das Timing

• E0 UART Daten Port. Über diese Adresse können Daten gesendet oder empfangen werden.
• E1 UART Control Port, über diesen Port können bestimmte Parameter für das UART gesetzt oder aber bestimmte Zustände abgefragt werden. Die Programmierung ist allerdings recht kompliziert.
• E4 Timer Kanal 0. Dieser setzt die Übertragungsrate für den Sender (Transmitter).
• E5 Timer Kanal 1. Dieser setzt die Übertragungsrate für den Empfänger (Receiver).
• E7 Timer Control, über diese Adresse werden Timer Parameter eingestellt.

• SC1, SC0 bestimmen den Timer, der programmiert werden soll. Für Kanal 0 ist das SC1,SC0=0,0 und für Kanal 1 SC1,SC0=0,1
• RL1, RL0 bestimmen, in welcher Reihenfolge das Teilerwort geschickt wird. Die Bits werden beide auf 1,1 gesetzt, dies entspricht dem üblichen Modus des Z80 Prozessors (erst das niederwertige Byte)
• M2, M1, M0 bestimmen den Zählmodus. Hier wird 0,1,1 gewählt, was einem Rechteckgenerator mit Teilung 1:1 entspricht.
• BCD gibt noch die Art der Teilung an, sie ist auf 0 zu setzen. Das entspricht einer Binärteilung.

	timer   equ     0e7h
        baud0   equ     0e4h
        word    equ     0011$0110b
        value   equ     417

doit:   mvi     a,wrd
        out     timer
        mvi     a,low value
        out     baud0
        mvi     a,high value
        out     baud0
        ret

1000 baud=300
1010 value=4000000!/(32*baud)
1020 OUT &HE7,&H36
1030 OUT &HE4,value MOD 256
1040 OUT &HE4,value\256
1050 RETURN

program BaudRate;
const
  Word   = $36;
  Baud0  = $E4;
  Value  = 417;

procedure bd_set(Word, Baud0,
                 Value : integer);
const
  Timer  = $E7;
begin
  port[Timer] := Word;
  port[Baud0] := lo(Value);
  port[Baud0] := hi(Value);
end;

begin
  bd_set(Word, Baud0, Value);
end.

Was ist nun das XBIOS?

        CALL    USERF
        DW      XBIOS_FUN

1. Disk Driver, z.B. Ausführen direkter UPD765 Controller Kommandos
2. SIO Driver
3. Terminal Emulator, Infos über den Bildschirm
4. Tastatur, Tastendefinition wie unter SETKEYS
5. Verschiedenes, z.B. Zugriff auf JOYCE Video RAM

• Funktion 1: Initialisierung des UART

  XBIOS_FUN:	00B6H
  Subfunktion:	UART Werte setzen
  Register:	Accu	Gewählter Modus
  		00H: Kein Handshake
  		FFH: Handshake
  	D	Anzahl Stop Bits
  		0 : 1 Stop Bit
  		1 : 1,5 Stop Bits
  		2 : 2 Stop Bits
  	E	Parität
  		0 : Keine
  		1 : Ungerade
  		2 : Gerade
  	H	Anzahl Datenbits des Enpfängers
  	L	Anzahl Datenbits des Senders (5, 6, 7 o. 8)
  Subfunktion:	UART Bits DTR und RTS setzen/löschen
  Register:	Accu	7DH RTS ein
  		7EH RTS aus
  		7FH DTR ein
  		80H DTR aus

• Funktion 2: Baudraten setzen

  XBIOS_FUN:	00B9H
  Register:	H kodierte Baudrate für Empfänger
  	L kodierte Baudrate für Sender

  Die Kodierung lautet

  Code:	0:	—	8:	1200 Bd
  	1:	50 Bd	9:	1800 Bd
  	2:	75 Bd	10:	2400 Bd
  	3:	110 Bd	11:	3600 Bd
  	4:	134,5 Bd	12:	4800 Bd
  	5:	150 Bd	13:	7200 Bd
  	6:	300 Bd	14:	9600 Bd
  	7:	600 Bd	15:	19200 Bd

• Funktion 3: UART Werte lesen

  XBIOS_FUN:	00BCH
  Nach Aufruf dieser Funktion sind die Register wie folgt belegt:
  	Accu	00H: kein Handshake
  		FFH: Handshake
  	B	Kodierte Epfänger Baudrate
  	C	Kodierte Sender Baudrate
  	D	Stop Bits (s.o.)
  	E	Parität (s.o.)
  	H	Datenbits des Empfängers (s.o.)
  	L	Datenbits des Senders (s.o.)

        CALL USERF      ;Laden der UART Werte
        DW   00BCH
        MOV  H,B        ;Empfänger so lassen
        MVI  L,6        ;Sender 300 Baud
        CALL USERF      ;Rate setzen
        DW   00B9H

INIT:   LHLD 1          ;BIOS Basis Adresse
        LXI  B,3*(30-1) ;Offset laden
        DAD  B          ;Vektor berechnen
        SHLD USERF+1    ;Als Sprungziel speichern
        RET
USERF:  JMP  $-$        ;Sprung zur BIOS Funktion 30

Z80 UART

• RxCA: Receiver Character Available - zeigt an, ob ein Zeichen empfangen wurde (RxCA = 1) oder noch nicht (RxCA = 0)
• TxBE: Transmitter Buffer Empty - zeigt an ob ein neues Zeichen gesendet werden kann (TxBE = 1) oder nicht (TxBE = 0)

OUTPUT: PUSH PSW        ; Zeichen retten
WAIT:   IN   0E1H       ; Warten bis Zeichen da
        ANI  0000$0100B
        JZ   WAIT
        POP  PSW
        OUT  0E0H       ; Ausgabe
        RET

• PE: Parity error - die empfangene Parität entspricht nicht dem eingestellten Wert
• OE: Overrun error - zeigt an, daß ein empfangenes Zeichen nicht rechtzeitig gelesen und von einem folgenden Zeichen überschrieben wurde
• FE: Framing error - zeigt einen Fehler im Datenformat an

ERROR:  MVI  A,1
        OUT  0E1H       ; RR1 adressieren
        IN   0E1H       ; Fehler einlesen
        PUSH PSW
        MVI  A,0
        OUT  0E1H       ; RR0 adressieren
        POP  PSW
        ANI  0111$0000B ; Zero Flag beeinflussen
        RET

• CTS: Clear to Send - das angeschlossene Gerät kann Daten empfangen, wenn CTS = 1 ist
• DSR: Data Set Ready - das angeschlossene Gerät ist betriebsbereit, wenn DSR = 1 ist
• DCD: Data Carrier Detected - zeigt an, ob vom angeschlossenen Modem oder Akustik-Koppler das Trägersignal anliegt, wenn DCD = 1 ist.

STATUS: MVI  A,0001$0000B
        OUT  0E1H       ; Reset einmal
        OUT  0E1H       ; .. zweimal
        IN   0E1H       ; Externe Signale lesen
        ANI  0011$1000B ; Bits maskieren
        RET

SENDBR:	MVI	D,1001$1010B	; Maske für BREAK
	MVI	E,30		; Länge des BREAK-Signals ist
				; 300 Millisekunden
SNDBR1:	MVI	A,1		; RR1 adressieren
	OUT	0E1H
	IN	0E1H		; Einlesen
	ANI	0000$0001B	; Testen des "ALL DONE" Bits
	JZ	SNDBR1		; Warten bis gesetzt
;
; Nun wird das BREAK-Signal gesendet
;
SETBIT:	MVI	A,5		; WR5 adressieren
	OUT	0E1H
	LDA	TXBITS		; Bits für Sender laden
				; Diese Bits stehen wie folgt:
				; x00x$xxxx  5 Bits
				; x01x$xxxx  7 Bits
				; x10x$xxxx  6 Bits
				; x11x$xxxx  8 Bits
	ORA	D		; Ausgabe BREAK,
	OUT	0E1H		; TXENABLE, RTS
;
; Jetzt Verzögerung von 300 Millisekunden durchführen
;
	MOV	A,E		; Verzögerungswert
	CALL	DELAY
;
; Die Zeit ist abgelaufen.
; Sender in den normalen Zustand versetzen.
;
	MVI	A,5		; WR5 adressieren
	OUT	0E1H
	LDA	TXBITS		; Bits für Sender erneut laden
	ORI	1000$1010B	; Kein BREAK
	OUT	0E1H		; Aber TXENABLE und RTS
	RET			; Fertig
;
; Beispiel für eine Verzögerungsroutine
; Hier für 10 Millisekunden
;
DELAY:	LD	C,40		; Entspricht 4 MHz
DELAY2:	LD	B,70
DELAY3:	DEC	B
	JP	NZ,DELAY3
	DEC	C
	JP	NZ,DELAY2
	DEC	A
	JP	NZ,DELAY
	RET

Schluß