Joyce Character Set

Beneath the standard character set the Joyce uses some more characters which may be used e.g. for window frames. The manual describes the changeover to different national fonts (selected by the ESCape sequence ESC 2 n):

The above output may be generated by the following program written in MALLARD-BASIC:

Find the listing here

Some characters of the extended set overlap the range of control characters. To use them as extended characters they must be prefixed by the ESCape character. The complete extended character set looks like follows:

Setting `LANGUAGE 0` (USA)	Setting `LANGUAGE 2` (Germany)

This output may be generated e.g. by the following program written in MALLARD-BASIC:

10 OPTION NOT TAB
20 INPUT "Zeichensatz (0-7) ";Zeichen
30 IF Zeichen<0 OR Zeichen>7 GOTO 20
40 PRINT CHR$(27);"2";CHR$(Zeichen);
50 PRINT:PRINT:PRINT:
60 PRINT "    JOYCE Zeichensatz - LANGUAGE =";Zeichen:PRINT
70 PRINT "    00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F"
80 PRINT "    -----------------------------------------------"
90 PRINT "    (ESCape vorweg)"
100 CH0=1:CH1=0:CH2=31:GOSUB 180
110 PRINT "   (ASCII Spezial)"
120 PRINT "7F:                                              ";CHR$(127):PRINT
130 PRINT "    (Erweiterte Zeichen)"
140 CH0=0:CH1=128:CH2=255:GOSUB 180
150 PRINT:PRINT:PRINT
160 END
170 '
180 FOR I=CH1 TO CH2 STEP 16
190 : IF I=0 THEN PRINT "0";
200 : PRINT HEX$(I);": ";
210 : FOR J=0 TO 15
220 :: IF CH0=1 THEN PRINT CHR$(27);
230 :: PRINT CHR$(I+J);"  ";
240 : NEXT
250 : PRINT
260 NEXT
270 PRINT
280 RETURN

Here for the Listing

The same output created by the following TURBO Pascal program:

program JOYCEcharacter(input,output);

procedure hex(x:integer);

  procedure nibb(b:integer);
  const
    hx : array[0..15] of char='0123456789ABCDEF';
  begin
    write(hx[b and $0F]);
  end;

Begin {hex}
  nibb(x shr 4);
  nibb(  x    );
End;

procedure PutLine(ch1,ch2:integer);
var
  i,j          : integer;
Begin
  i:=ch1;
  repeat
    hex(i);
    write(': ');
    for j:=0 to 15 do
    begin
      if (i+j)<ord(' ') then write(chr(27));
      write(chr(i+j),'  ');
    end;
    writeln;
    i:=i+16;
  until i>ch2;
  writeln;
End;

BEGIN
  writeln('    JOYCE Zeichensatz');
  writeln('    00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F');
  writeln('    -----------------------------------------------');
  writeln('    (ESCape vorweg)');
  PutLine($00,$1F);
  writeln('   (ASCII Spezial)');
  writeln('7F:                                              ',chr($7F));
  writeln('   (Erweiterte Zeichen)');
  PutLine($80,$FF);
END.

Here for the listing

Using assembler the BDOS functions 2 and 6 are available for console output. Of course output through BIOS may be performed, too.

Call by function BDOS 6 Call by function BDOS 2 Call by function BDOS 2, corrected, and call by BIOS

The characters 0xFDH, 0xFEH and 0xFFH are functions to the call and will not be displayed.

The tab character (0x09H) will not be displayed correctly.

Here all characters are displayed correctly.

The sample utility allows the output as above:

	title	Character Representation for the JOYCE
	name	('JOYCHAR')

; This small utility displays all available characters of the
; Joyce using BDOS an BIOS calls.

; Select calls by parameters:

; JOYCHAR 6	Direct console output
;		It is not possible to display the characters
;		0xFDh, 0xFEh and 0xFFh
; JOYCHAR 2	Console output
;		The tabulator will be handled
; JOYCHAR 2T	Console output with suppressed tabulator
;		The tabulator will not be handled
; JOYCHAR B	BIOS console output
;
; Only calls 'JOYCHAR 2T' and 'JOYCHAR B' are displaying the complete
; character set

OS	equ	0000h
BDOS	equ	0005h
TPAtop	equ	BDOS+1
FCBnam	equ	005dh

.conout	equ	  2
.condir	equ	  6
.string	equ	  9
.consta	equ	109

_COT	equ	4		; BIOS function

null	equ	00h
tab	equ	09h
lf	equ	0ah
cr	equ	0dh
esc	equ	1bh
eot	equ	'$'
DEL	equ	7fh
SPC	equ	80h

	ld	sp,(TPAtop)	; Load stack
	ld	a,(FCBnam)	; Fetch parameter
	cp	' '		; End if no parameter available
	jr	z,Help
	sub	'0'		; Make binary from ASCII
	cp	.conout
	jr	z,setcon
	cp	.condir
	jr	z,setcon
	cp	'B'-'0'		; Test BIOS
	jr	nz,Help		; Invalid
	call	BIOSini
	jr	gochar
Help:
	ld	de,$HELP
	call	String		; Print small help text
	jp	OS
setcon:
	ld	(concall),a	; Save function
	cp	.conout
	call	z,chgtab	; Turn off tab handling on request
gochar:
	ld	de,$HEAD
	call	String		; Print headline
	ld	c,null		; Set start character
	ld	b,2		; Number of lines
	call	put		; Print in range 0x00h-0x1Fh
	ld	de,$DEL
	call	String
	ld	a,DEL
	call	conout		; Print special character
	ld	de,$EXTEND
	call	String
	ld	c,SPC		; Set start character
	ld	b,8		; Number of lines
	call	put		; Print in range 0x80h-0xFFh
	jp	OS		; End
;
; Print line with extended characters
; Start character in reg C, number of lines in reg B
;
put:
	ld	a,c		; Get start character
	call	hexout		; Print as hex
	ld	de,$DELIM
	call	String		; Print delimiter
	push	bc
	ld	b,16		; Number of characters within one line
put2:
	ld	a,c		; Get character
	cp	' '		; Test control
	call	c,ESCout	; Print ESCape if so
	ld	a,c
	call	conout		; Print character
	ld	de,$BLANK
	call	String		; Print space
	inc	c		; Next character
	djnz	put2
	call	crlf		; Close line
	ld	a,c
	pop	bc
	ld	c,a
	djnz	put
crlf:
	ld	de,$CRLF
	call	String
	ret
;
; Print byte in Accu as characters
;
hexout:
	push	af
	rra			; Get upper bits
	rra
	rra
	rra
	call	prhex		; Print
	pop	af		; Get lower bits
prhex:
	and	00001111b	; Mask bits
	add	a,90h
	daa			; Convert to ASCII
	adc	a,40h
	daa
	jr	conout		; Print
;
; Print ESCAPE character
;
ESCout:
	ld	a,esc
;
; Print ESCAPE character in Accu
;
conout:
	push	bc
	push	de
	push	hl
	ld	hl,(CONvec)	; Get output vector
	call	jp.r		; Print it
	pop	hl
	pop	de
	pop	bc
	ret
concall:
	ds	1
;
jp.r:
	jp	(hl)
;
; Character output through BDOS
;
BDOS.COT:
	ld	e,a		; Unpack character
	ld	a,(concall)	; Get BDOS function
	ld	c,a
	call	BDOS		; Output
	ret
;
; Character output through BIOS
;
BIOS.COT:
	ld	c,a		; Unpack character
	ld	hl,(@COT)	; Get BIOS address
	call	jp.r		; Output
	ret
;
; Put string ^DE to console
;
String:
	push	bc
	push	de
	push	hl
	ld	c,.string
	call	BDOS		; Put it
	pop	hl
	pop	de
	pop	bc
	ret
;
; Turn off tab handling on request
;
chgtab:
	ld	a,(FCBnam+1)	; Get character following '2'
	cp	'T'		; Test suppressing of tab handling
	ret	nz		; No	
	ld	de,-1
	call	conset		; Get state of console
	ex	de,hl
	set	2,e		; Modify tab bit
conset:
	ld	c,.consta
	call	BDOS		; Attache state of console
	ret
;
; Calculate BIOS vector referring to console output
;
BIOSini:
	ld	hl,(OS+1)	; Get BIOS base address
	ld	de,3*(_COT-1)
	add	hl,de
	ld	(@COT),hl	; Save address for console output
	ld	hl,BIOS.COT
	ld	(CONvec),hl
	ret
@COT:
	ds	2
CONvec:
	dw	BDOS.COT
;
$HELP:
	db	cr,lf,lf
	db	'his small utility displays all available characters of the'
	db	cr,lf
	db	'Joyce using BDOS an BIOS calls.'
	db	cr,lf,lf
	db	'Select calls by parameters:'
	db	cr,lf,lf
	db	'JOYCHAR 6',tab,'Direct console output'
	db	cr,lf
	db	tab,tab,'It is not possible to display the characters'
	db	cr,lf
	db	tab,tab,'0xFDh, 0xFEh and 0xFFh'
	db	cr,lf
	db	'JOYCHAR 2',tab,'Console output'
	db	cr,lf
	db	tab,tab,'The tabulator will be handled'
	db	cr,lf
	db	'JOYCHAR 2T',tab,'Console output with suppressed tabulator'
	db	cr,lf
	db	tab,tab,'The tabulator will not be handled'
	db	cr,lf
	db	'JOYCHAR B',tab,'BIOS console output'
	db	cr,lf,lf
	db	'Only calls ''JOYCHAR 2T'' and ''JOYCHAR B'' are displaying the complete'
	db	cr,lf
	db	'character set'
	db	cr,lf,lf,eot
$HEAD:
	db	cr,lf,lf
	db	'    00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F'
	db	cr,lf
	db	'    -----------------------------------------------'
	db	cr,lf
	db	'    (ESCape praefix)'
	db	cr,lf,eot
$DEL:
	db	'   (ASCII special)'
	db	cr,lf
	db	'7F:                                              '
	db	eot
$EXTEND:
	db	cr,lf
	db	'    (Extended characters)'
$CRLF:
	db	cr,lf,eot
$DELIM:
	db	': '
	db	eot
$BLANK:
	db	'  '
	db	eot

	end

Here for the listing

The examples show the proper output of the extended characters running MALLARD-BASIC as well as TURBO-Pascal. Other PASCAL compilers (e.g PROSPERO) do not work properly, neither Microsoft BASIC does.

Because Joyce characters are stored as a matrix of 8x8 bytes in the character memory they may be modified easily. A base article will be found here. More examples will be found in a German article, called Superscript. I myself modified the character set for characters as used in the SOL-20 machine.

Back to firmware