{ PICS0C.INC  Pascal Integrated Communications System Overlays }
{ 5/25/87 ver 1.6  Copyright 1987 by Les Archambault}

Overlay procedure Show_user_stats;
   var Tstr:strtad;
       time_on,time_left,time_today,time_total:integer;
   begin
     seek(logr_file,0);
     read(logr_file,logr_rec);
     Tstr := FormTAD(login_t);
     Writeln(USR);
     Writeln(USR, 'Login              : ', Tstr);
     if user_rec.access>=val_acc then write(usr, 'Eingetr. Benutzer  : ')
                                 else write(usr, 'Gast-Benutzer      : ');
     writeln(usr,user_rec.fn,' ',user_rec.ln);
     Writeln(USR);
     timer(time_on, time_left);
     time_today := user_rec.time_today + time_on;
     time_total := user_rec.time_total + time_on;
     Writeln(USR, 'Anrufer Nummer     : ', logr_rec.user);
     Writeln(USR, 'Access Zeit heute  : ', time_today);
     Writeln(USR, 'Access Zeit total  : ', time_total);
     Tstr := FormTAD(user_rec.laston);
     Writeln(USR, 'Letzter Anruf      : ', Tstr);
     Writeln(USR, 'Zul. geles. Brief  : ', user_rec.lasthi);
     Writeln(usr, 'Uploads bis heute  : ', user_rec.upload);
     Writeln(usr, 'Downloads bis heute: ', user_rec.download);
     writeln(usr);
   end;

Overlay Procedure Update_Newin(Xfrname:filename);
   var i:integer;
       t:tad_array;
       found:boolean;

   begin
     found:=false;
     if ok then
       begin
         setsect(homdrv,homusr);
         i:=pred(filesize(nwin_file));
         while (ok) and (i>=0) and (not found) do
           with nwin_rec do
             begin
               seek(nwin_file,i);
               read(nwin_file,nwin_rec);
               if xfrname=name then
                 begin
                   dnloads:=succ(dnloads);
                   gettad(t);
                   last_dnload:=t;
                   found:=true;
                   seek(nwin_file,i);
                   write(nwin_file,nwin_rec);
                 end;
               i:=pred(i);
             end;
       end;
   end;

{End of PICS0C.INC }