(***************************************************************************)
(*   Bibliotheks-Modul LAUF.BIB                                            *)
(*                                                                         *)
(*   Bringt bei Bedarf etwas Leben in Form einer Laufschrift auf dem       *)
(*   Bildschirm.                                                           *)
(*   (t L_str127)                                                          *)
(*   (v LaufRec)                                                           *)
(*   p InitLaufschrift(x,y : integer; Satz : string[127]; B, K : integer)  *)
(*     Dabei ist                                                           *)
(*       x, y : die Bildschirmposition fur die Laufschrift                 *)
(*       Satz : die Laufschrift selbst                                     *)
(*       B    : die Anzahl der angezeigte Laufschriftspalten               *)
(*       K    : die TimeOut-Konstante                                      *)
(*                                                                         *)
(*   p Lauf   Bei jedem Aufruf wird eine Variable inkrementiert. Wir der   *)
(*            Wert von K erreicht, so wird die Laufschrift ein Zeichen     *)
(*            weitergerueckt und die Variable wieder auf Null gesetzt      *)
(***************************************************************************)

TYPE L_str127 = STRING[127];
VAR  Lauf_Rec : RECORD
                  TimeOut, LaufWindow, Lauf_X, Lauf_Y, LaufBreite : integer;
                  LaufSchrift : STRING[127]
                END;

PROCEDURE InitLaufschrift(x,y : integer; Satz : L_str127;
                          Breite, Konstante : integer);
  VAR i : integer;
  BEGIN
    WITH Lauf_Rec DO
      BEGIN
        Lauf_X:=x; Lauf_Y:=y; LaufBreite:=Breite;
        LaufSchrift:=Satz; FOR i:=1 TO Breite DO LaufSchrift:=' '+Laufschrift;
        TimeOut:=Konstante; LaufWindow:=ScreenPtr
      END
  END; (* InitLaufSchrift *)

PROCEDURE Lauf;
  CONST Count : integer = 0;
  VAR temp, t_x, t_y : integer;
  BEGIN
    WITH Lauf_Rec DO
    BEGIN
      Count:=succ(Count); IF Count<TimeOut THEN exit;
      t_x:=WhereX; t_y:=WhereY;
      Count:=0; temp:=ScreenPtr; ChangeWindow(LaufWindow);
      gotoxy(Lauf_X,Lauf_Y); write(copy(LaufSchrift,1,LaufBreite));
      LaufSchrift:=LaufSchrift+LaufSchrift[1]; delete(LaufSchrift,1,1);
      ChangeWindow(temp); gotoxy(t_x,t_y)
    END
  END; (* Lauf *)