Kodierung des SLR Assemblers

Bei einem ersten Blick in das Programm fällt auf, dass der Kode nach einigen Datenfeldern ohne Sinn zu sein scheint.

	jp	l2459
; Im Bereich 0103H - 01A5H finden sich Daten im Klartext
l0103:
	db	'Z3ENV'
	db	1
	dw	0
	dw	0131h
	db	0
	db	80
	db	60
	db	0
	..	..
	..	..
; Der erste kodierte Bereich beginnt bei 01A6H und ended bei 245FH
l01a6:
;	ORIGINAL		KLARTEXT
;	--------		--------
	cp	h		; db	05eh
	add	a,(hl)		; db	13,'Extra Operand'
	adc	a,d
	inc	a
	ret	pe
	add	hl,sp
	jp	nz,9e10h
	jr	c,017bh
	add	hl,sp
	jp	nz,0c837h
	rst	38h		; db	-1
	..	..
	..	..
; Dekodierung beginnt bei Adresse 2459H
l2459:
	ld	hl,l2460	; Versteckte Laenge laden
	ld	de,l01a6	; Erste Startadresse laden
	call	l246d		; Dekodieren
	ld	hl,l633f	; Dann nochmal fuer Teil 2
	ld	de,l2486
	call	l246d
	jr	l24c1		; Assembler starten
l246d:
	or	a
	sbc	hl,de		; Laenge berechnen
	srl	h		; Halbieren
	rr	l
	ld	b,l		; Niederes Byte
	ld	c,h		; Hoeheres Byte
	jr	z,l2479
	inc	c
l2479:
	ex	de,hl
l247a:
	rrc	(hl)		; Echten Kode laden
	inc	hl
	rlc	(hl)
	inc	hl
	djnz	l247a
	dec	c
	jr	nz,l247a
	ret
; Der zweite kodierte Bereich beginnt bei 2486H und ended bei 633EH
l2486:
;	ORIGINAL		KLARTEXT
;	--------		--------
	ld	(hl),h		; ld	a,(6365H)
	or	d
	add	a,0dbh		; or	a
	sub	l		; jp	z,2905H
	add	a,d
	ld	d,d
	..	..
	..	..
; Der Assembler startet hier nach Entschluesselung
l24c1:
;	ORIGINAL		KLARTEXT
;	--------		--------
	or	0f6h		; ld	sp,(0006h)
	inc	bc
	nop
	dec	d		; ld	hl,(0109h)
	ld	(de),a
	add	a,b
	..	..
	..	..

In der Entschlüsselungsroutine ab 2459H werden zwei Programmteile entschlüsselt. Nach der jeweiligen Berechnung der Länge des Kodes werden die beiden Teile durch abwechselndes Rechts- und Linksschieben in den korrekten Kode gewandelt.

Bei genauer Untersuchung findet sich ein Sicherheitsmechanismus. Vor dem Schreiben in eine Datei wird geprüft, ob es sich um eine Originaldatei handelt. Stimmt der Test nicht, dann lässt sich keine Datei beschreiben. Das erwartete Resultat steht in Adresse 01A6H — das ist die erste Adresse im verschlüsselten Bereich.

;
; Puffer bei korrekter Seriennummer auf Diskette schreiben
;
l6076:
	push	hl
	push	bc
	push	de
;
; !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
; !!! Der folgende  Kode ist einfach aber trickreich. Er   !!!
; !!! prueft die Seriennummer und beendet die Routine ohne !!!
; !!! auf Dikette zu schreiben, wenn die Nummer falsch ist !!!
; !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;
	ld	hl,1500h	; Nett kodiert
	ld	a,0		; .. noch besser
	or	a		; .. dito.
	rra			; .. dito.
	adc	hl,hl		; .. dito.
	ld	b,6
l6084:
	add	a,(hl)
	inc	hl
	djnz	l6084
	ld	de,d7a0h	; Offset 01a6h-(2a00h+6)
	add	hl,de		; .. auch gut
	cp	(hl)
;
; !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;
	pop	de
	pop	bc
	pop	hl
	ret	nz		; .. Abbruch bei falscher S/N
	..	..		; Weiter mit Schreiben
	..	..

Wieder unübersichtlich programmiert wird getestet, ob die Seriennummer des Programms korrekt ist.

Es wird die Adresse, an der die Seriennummner — hier SB3051 — steht, geladen, allerdings statt 2A00H die halbe Adresse 1500H, die dann verdoppelt wird.
Dann wird die Summe der sechs Zeichen der Seriennummer gebildet.
Danach wird die Adresse über einen geheimnisvollen Offset auf das erwartete Byte berechnet und der Inhalt mit der Summe verglichen.
Stimmt der Vergleich nicht, erfolgt kein Schreiben in eine Datei.

Das Programm funktioniert mit oder ohne Übereinstimmung, aber nur bei korrektem Vergleich wird eine Ausgangsdatei erzeugt.

Zurück zum SLR Assembler