title	MLOAD Test Programm

; Das Programm stellt zum JOYCE gehoerige Routinen zur Verfuegung.

	aseg
	org	0200h

BDOS	equ	0005h

.condir	equ	6

esc	equ	1bh
eot	equ	'$'

; Sprungleiste

	jp	setmem
	jp	clrscr
	jp	atxy
	jp	idstrg

; ------------------------------------
;
; Speicherinitialisierung
; Registerpaar HL haelt die hoechste Speicheradresse
; Diese wird abgelegt und als Stackpointer verwendet
; Bei Rueckkehr haelt Registerpaar HL die erste freie Adresse
;
setmem:
	ld	(last),hl	; Adresse speichern
	pop	bc
	ld	sp,hl		; Stackpointer laden
	push	bc
	ld	hl,top		; Freie Adresse laden
	ret
;
; Bildschirm loeschen
;
clrscr:
	ld	a,'H'
	call	escout		; ESCape Sequenz ausgeben
	ld	a,'E'
	call	escout
	ret
;
; Cursor positionieren auf H=Reihe und L=Spalte
;
atxy:
	ld	a,'Y'
	call	escout		; Vorsoann ausgeben
	ld	a,h		; Reihe laden
	call	offs
	ld	a,l		; Spalte laden
offs:
	add	a,' '		; Offset addieren
	call	cot		; Und Ausgabe
	ret
;
; Zeichensequenz ESC <AKKU> ausgeben
;
escout:
	push	af
	ld	a,esc
	call	cot		; ESCape ausgeben
	pop	af		; Dann Akku
;
; Zeichen im Akku ausgebebn
;
cot:
	push	bc
	push	de
	push	hl
	ld	e,a
	ld	c,.condir
	call	BDOS		; Ausgabe
	pop	hl
	pop	de
	pop	bc
	ret
;
; Maschinennamen laden
;
idstrg:
	ld	de,$IDSTRG
	ret
$IDSTRG:
	db	'JOYCE/PCW 8256'
	db	eot
last:
	ds	2
top:

	end