Joker für Dateibearbeitung

Sie haben Ihre selbstprogrammierte Dateiverwaltung geladen und suchen nun einen bestimmten Eintrag. Leider haben Sie aber gerade die exakte Schreibweise des Suchbegriffes nicht im Kopf. Wenn Sie sich in dieser Situation wiedererkennen, dann dürfte Sie dieser Beitrag interessieren.

Jeder kennt sie von den Kopierprogrammen der Betriebssysteme: Die »Joker« oder »Wildcards« <*> und <?>. <*> darf Namensteile, <?> einen Buchstaben ersetzen. Das können wir auch in unseren eigenen Programmen verwenden. Mit der Funktion »Gleich« läßt sich schnell eine Datei auf passende Einträge durchsuchen. Dabei sind für die Maske auch Konstruktionen wie »Mü*er*n« erlaubt, die beispielsweise der Befehl »Copy« von MS-DOS nicht bearbeitet. Eigentlich sollte keine Dateiverwaltung und keine Datenbank ohne diese Funktion programmiert werden. Wie oft taucht die Frage auf »Maier mit ai, ei, ey oder ej ?« Wir tippen einfach »M??er« und schon werden alle passenden Einträge gesucht.
Oder man sucht in einer Adressenliste alle Gabis in München:
Vorname: Gab*
Nachname: *
Ort: München

Sollen alle Features der Maskenprogrammierung berücksichtigt werden, entsteht eine furchtbare Schlange von IF-Anweisungen. Das läßt sich durch Rekursion einigermaßen im Rahmen halten. Es wird immer nur der erste Buchstabe der Maske untersucht. Anschließend wird dieser und der dazu passende Teil des Vergleichstrings gelöscht, um wieder von vorne zu beginnen.

Obwohl Rekursionen immer etwas länger dauern, ist die Funktion auch in großen Dateien sehr schnell und CP/M-Programmierer können auf die Compiler-Option {$A-} verzichten, da der Rekursionsstack nicht benötigt wird.

Das Demo-Programm zeigt den Einsatz der Funktion zur Erstellung einer Indexdatei.

(Detlef Hoche/zi)

(********** Vergleich zweier Strings **********)
(* Die Funktion Gleich ergibt true, wenn die  *)
(* Maske auf den String Str passt. Maske darf *)
(* die Joker * und ? enthalten.	              *)
(* Es wird die Definition des Stringtyps      *)
(* WrkString vorausgesetzt.                   *)
(**********************************************)

function Gleich(Maske,Str:WrkString):boolean;
  var j:integer;CharFound:boolean;

begin {of Gleich}
j:=1;Gleich:=true;
if length(Maske)=0
  then begin if length(Str)>0 then Gleich:=false end
  else
    if (Maske[1]='*')
      then
        begin
        if length(Maske)>1 then
          begin
          CharFound:=false;j:=0;
          while (j<=length(Str)) and (not CharFound) do
            begin
            j:=j+1;
            if (Maske[2]=Str[j]) or (Maske[2]='?')
               or (Maske[2]='*') then CharFound:=true;
            end;
          delete(Maske,1,1);delete(Str,1,j-1);
          if length(Maske)>0
            then Gleich:=Gleich(Maske,Str);
          end;
        end
      else
        if (length(Maske)>0) and (length(Str)>0)
          then
            begin
            if (Maske[1]<>Str[1]) and (Maske[1]<>'?')
              then Gleich:=false
              else
                begin
                delete(Maske,1,1);delete(Str,1,1);
                Gleich:=Gleich(Maske,Str)
                end;
              end
            else if (length(Maske)>0) or (length(Str)>0)
                   then Gleich:=false
 end; {of Gleich}

Listing der Funktion »GLEICH«

program Demo_von_Gleich;
Type WrkString=String[20];
     Adresse=record Name:WrkString;
                    Strasse:WrkString;
                    Postleitzahl:String[4];
                    Ort:WrkString;
                    end;
const MaxZahl=25;
var i,j,Anzahl:integer;
    Liste:array[1..MaxZahl] of Adresse;
    Index:array[1..MaxZahl] of integer;
    Maske:Adresse;

{$I Gleich.bib }

procedure Eingabe(var DatenSatz:Adresse);
begin
with Datensatz do
    begin
    write('Name        : ');readln(Name);
    if Name<>'###'
      then
        begin
        write('Straße      : ');readln(Strasse);
        write('Postleitzahl: ');readln(Postleitzahl);
        write('Ort         : ');readln(Ort);
        end;
      end;
end;

begin {Hauptprogramm}
clrscr;
writeln('Demonstrationsprogramm für Funktion Gleich');
writeln;
write('Geben Sie eine Adressenliste ein');
writeln(' (Ende mit Name=###)');
i:=0;
repeat
  writeln;
  i:=i+1;
  Eingabe(Liste[i]);
until Liste[i].Name='###';
writeln;
write('Sie können nun mit einer Maske,');
writeln(' die die Joker * und ? enthalten');
writeln('darf, eine Indexdatei erstellen.');
writeln;writeln('Maske :');
Eingabe(Maske);
Anzahl:=0;
with Maske do
  For j:=1 to i-1 do
    begin
    if Gleich(Name,Liste[j].Name)
       and Gleich(Strasse,Liste[j].Strasse)
       and Gleich(Postleitzahl,Liste[j].Postleitzahl)
       and Gleich(Ort,Liste[j].Ort)
       then
         begin
         Anzahl:=Anzahl+1;
         Index[Anzahl]:=j;
         end;
    end;
writeln;
for j:=1 to Anzahl do
  with Liste[Index[j]] do
    writeln(Name,' ',Strasse,' ',Postleitzahl,' ',Ort);
end.

Dieses Listing zeigt den Einsatz der Funktion »GLEICH«

Hier die Funktion »Gleich« und hier das Demo-Programm