Wildcards und Parameter-Übergabe

Turbo-Pascal 2.0 unterstützt eine Vielzahl von CP/M-Funktionen. Leider gilt dies nicht für die Übergabe von Parametern beim Aufruf eines Programmes und die Verwendung von „Wildcards" in Dateinamen. Ein kurzes Programm schafft Abhilfe.

Der CCP hinterläßt einem Programm den Teil der aufrufenden Befehlszeile, der über den Namen des aufgerufenen Programmes hinausgeht. Dieser Rest steht im Speicherbereich $80...$FF (in $80 steht die Länge dieses Restes). In den darauffolgenden Speicherzellen findet man dann die entsprechenden Buchstaben der Befehlszeile in ASCII-Code. Die Datenstruktur entspricht genau einem String der maximalen Länge von 127 Zeichen, der ab $80 gespeichert ist. Durch die Variablen-Deklaration


VAR

PARAMETER:STRING[127] ABSOLUTE $0080;

werden dann die übergebenen Parameter zu einem String, auf den mit den üblichen Mitteln zugegriffen werden kann (Bild).
Das BDOS unterstützt Wildcards mit den Funktionen SEARCH_FOR_FIRST und SEARCH_FOR_NEXT. Diese Funktionen benötigen als Parameter die Adresse eines File-Control-Blocks und füllen als Seiteneffekt einen Puffer mit Einträgen aus dem Directory. Funktionswert ist, falls eine passende Datei gefunden wurde, eine Zahl zwischen 0 und 3. Diese Zahl verweist auf den Eintrag in Puffer, der den genauen Dateinamen enthält. Wurde keine passende Datei gefunden, ist der Funktionswert $FF.

Mit dem Befehl ASSIGN(DIR_FILE,GESUCHT) wird der File-Control-Block mit einem Dateinamen, der als Wildcards Fragezeichen enthalten darf, gefüllt. Der Befehl BDOS(CPM_SET_DMA_ADDRESS,ADDR(DIR_PUFFER)) sorgt dafür, daß bei den folgenden Directory-Zugriffen der DIR_PUFFER mit den Directory-Einträgen gefüllt wird. Beim BDOS-Aufruf werden dann als Parameter die Funktionsnummer und die Adresse des File-Control-Blocks übergeben. Der File-Control-Block steht dabei ab Byte 12 des Speicherbereiches von DIR_FILE. Die Funktion MAKE_NAME macht aus diesem Funktionswert einen normalen Filenamen bzw. einen Leerstring, falls keine weitere Datei gefunden wurde.

Zur Übernahme der Parameter reicht die gezeigte String-Deklaration. Das erste Zeichen des Strings ist aber das trennende Leerzeichen und muß gelöscht werden.

Um mehrere Dateien mit Wildcards anzusprechen, wird zuerst die Funktion SEARCH_FOR_FIRST mit einem Dateinamen, der Fragezeichen enthält, aufgerufen. Funktionswert ist ein Dateiname. Alle weiteren Dateinamen erhält man mit der Funktion SEARCH_FOR_NEXT. Falls es keine weitere Datei gibt, ist der Leerstring der Funktionswert. Die Aufrufe der Funktionen SEARCH_FOR_FIRST und SEARCH_FOR_NEXT dürfen durch keine anderen Dateizugriffe unterbrochen werden. Es empfiehlt sich also, alle Dateinamen in einem Array zwischenzuspeichern.

Um das Format der Aufrufe zu zeigen, ist im abgedruckten Programm der Dir-Befehl in Turbo-Pascal implementiert. Es übernimmt als Parameter eine Dateibezeichnung mit Fragezeichen und gibt die Namen der passenden Dateien aus.

Literatur

[1] Turbo-Pascal 2.0 Reference Manual. Fa. Borland.
[2] CP/M 2.0 Interface Guide. Fa. Digital Research.

PROGRAM DIRECTORY_und_PARAMETER_DEMO;

(* C by D.Michelsen,   22.06.85                                     *)
(* System: Apple II+ mit Z80-Karte, CP/M-Version 2.20B              *)
(* Dieses Programm verwendet nur Standardaufrufe von Turbo und CP/M *)

CONST CPM_SEARCH_FOR_FIRST=17;
      CPM_SEARCH_FOR_NEXT =18;
      CPM_SET_DMA_ADDRESS =26;

TYPE USER_NAME=STRING[14];

     DIR_ENTRY=RECORD
                DRIVE_CODE:BYTE;
                FILE_NAME :ARRAY[1.. 8] OF CHAR;
                FILE_TYPE :ARRAY[1.. 3] OF CHAR;
                SYSTEM_USE:ARRAY[1..20] OF BYTE;
               END;

VAR PARAMETER :STRING[127] ABSOLUTE $0080;
    DIR_FILE  :FILE;
    DIR_PUFFER:ARRAY[0..3] OF DIR_ENTRY;

FUNCTION MAKE_NAME(DIR_CODE:BYTE):USER_NAME;

 VAR NAME:USER_NAME;
     HELP:BYTE;

 BEGIN;
  IF DIR_CODE=$FF
  THEN MAKE_NAME:=''
  ELSE WITH DIR_PUFFER[DIR_CODE]
       DO BEGIN;
           IF MEM[ADDR(DIR_FILE)+12]=0
           THEN NAME:=''
           ELSE NAME:=CHR(64+MEM[ADDR(DIR_FILE)+12])+':';
           FOR HELP:=1 TO 8
           DO IF FILE_NAME[HELP]<>' '
              THEN NAME:=NAME+CHR($7F AND ORD(FILE_NAME[HELP]));
           NAME:=NAME+'.';
           FOR HELP:=1 TO 3
           DO IF FILE_TYPE[HELP]<>' '
           THEN NAME:=NAME+CHR($7F AND ORD(FILE_TYPE[HELP]));
           MAKE_NAME:=NAME;
          END;
 END;

FUNCTION SEARCH_FOR_FIRST(GESUCHT:USER_NAME):USER_NAME;

 BEGIN;
  ASSIGN(DIR_FILE,GESUCHT);
  BDOS(CPM_SET_DMA_ADDRESS,ADDR(DIR_PUFFER));
  SEARCH_FOR_FIRST:=MAKE_NAME(BDOS(CPM_SEARCH_FOR_FIRST,ADDR(DIR_FILE)+12));
 END;

FUNCTION SEARCH_FOR_NEXT:USER_NAME;

 BEGIN;
  SEARCH_FOR_NEXT:=MAKE_NAME(BDOS(CPM_SEARCH_FOR_NEXT,ADDR(DIR_FILE)+12));
 END;

VAR FILES:STRING[16];

BEGIN;
 FILES:=SEARCH_FOR_FIRST(COPY(PARAMETER,2,LENGTH(PARAMETER)-1));
 WHILE FILES<>''
 DO BEGIN;
     WRITELN(FILES);
     FILES:=SEARCH_FOR_NEXT;
    END;
END.

Den DIR-Befehl verwirklicht dieses Programm in Turbo-Pascal 2.0 unter CP/M-80