Turbo Menu

Turbo Menue

Von CP/M aus lassen sich alle COM-Files durch Eingabe des Dateinamen (ohne Extension!) starten.

Das Programm »Turbo-Menue« erzeugt ein Directory bestehend aus COM-Files. Jedes dieser Files kann mit Hilfe zweier Tasten markiert werden (Taste <s> = links, <d> = rechts). Durch Drücken der < RET >-Taste wird das markierte Programm ausgefürt.

Für die Rechner, deren Zeilenbreite < > 80 Zeichen/Zeile beträgt, kann im Programmkopf die Zeile CONST spalten=80 entsprechend geändert werden.

Zu beachten ist, daß sich das Programm nur als COM-File von CP/M aus ausführen läßt (d.h., man muß das Programm auf Diskette compileren, Turbo-Pascal verlasssen und dann von CP/M aus das Programm aufrufen).

 1: PROGRAM run_demo(INPUT,OUTPUT);
 2:
 3: { run erzeugt ein Dirctory bestehen  aus COM-Files . Jedes }
 4: { der Files kann man mit Hilfe der Tasten <s> (links)  und }
 5: { <d> (rechts) markieren . Eine  markierte Datei kann dann }
 6: { durch Druecken der <RETURN>-Taste ausgefuehrt werden.    }
 7: { Dieses Programn kann nur dann verwendet werden , wenn es }
 8: { auf Diskette compilert und von CP/M aus aufgerufen wird. }
 9:
10: { Die folgende CONST-Anwelsung muss fuer Bildschirme, die  }
11: { nicht mit 80 Zeichen/Zeile arbeiten, geaendert werden !  }
12:
13: CONST spalten = 80;                { Anzahl Zeichen/ Zeile }
14:
15: TYPE longword   = STRING[255];
16:      shortword  = STRING[11];
17:
18: VAR DMA     : STRING[128];
19:     FCB     : shortword ABSOLUTE $5C; { File Control block }
20:     eingabe : longword;
21:     name    : ARRAY[0..63] OF shortword;
22:     r,i     : INTEGER;
23:     a,z,n,code : BYTE;
24:     ein     : CHAR;
25:     ext     : STRING[3];
26:     datei   : FILE;
27:
28:
29: PROCEDURE markiere(on:BOOLEAN);
30: { Der ausgewaehlte Filename wird mit Hilfe der inversen    }
31: { Schrift markiert                                         }
32: BEGIN
33:   GOTOXY((i MOD n)*15+1,(i DIV n)+5);
34:   IF on THEN LOWVIDEO
35:         ELSE NORMVIDEO;
36:   WRITE(COPY(name[i],1,8),'.',COPY(name[i],9,3));
37:   IF on THEN NORMVIDEO
38:         ELSE LOWVIDEO
39: END;
40:
41: BEGIN
42:   n:=spalten DIV 15; { Anzahl der COM-Dateinamen pro Zeile }
43:   CLRSCR;
44:   z:=0;                                     { File-Zaehler }
45:   FCB:='????????COM';
46:   mem[$5c]:=0;
47:   bdos(26,addr(DMA));                  { setze DMA-Adresse }
48:   a:=bdos(17,$5C);             { suche nach ersten Eintrag }
49:   WHILE a<255 DO
50:   BEGIN
51:     a:=a*32+1;  { rel. Adresse des Filenamen in DMA-Puffer }
52:     name[z]:='';
53:     FOR i:=0 TO 10 DO name[z]:=name[z]+DMA[a+i];
54:     GOTOXY((z MOD n)*15+1,(z DIV n)+5);
55:     WRITE(COPY(name[z],1,8),'.',COPY(name[z],9,3));
56:     a:=bdos(18,$5C);        { suche nach naechstem Eintrag }
57:     z:=z+1;
58:   END;
59:   z:=z-1;                       { z=Anzahl des COM-Files-1 }
60:   code:=0; i:=0;
61:   markiere(TRUE);         { markiere erstes (nulltes) File }
62:   WHILE code<>13 DO
63:   BEGIN
64:     READ(KBD,ein);
65:     code:=ORD(UPCASE(ein));
66:     IF code=68 THEN r:=1                     { nach rechts }
67:     ELSE IF code=83 THEN r:=-1                { nach links }
68:     ELSE r:=0;
69:     IF r<>0 THEN
70:     BEGIN
71:       markiere(FALSE);               { Markierung loeschen }
72:       i:=i+r;
73:       IF i>z THEN i:=0
74:       ELSE IF i<0 THEN i:=z;
75:       markiere(TRUE);                  { Markierung setzen }
76:     END
77:   END;
78:   ASSIGN(datei,COPY(name[i],1,POS(' ',name[i])-1)+'.COM');
79:   EXECUTE(datei); { Ausfuehrung d. ausgewaehlten Com-Files }
80: END.
81:

[Turbo-Pascal source]