Prüfsummenprogramm für Joyce

Listings für die CPC-Modelle werden in dieser Zeitschrift seit einiger Zeit mit Prüfsummen abgedruckt. Für Joyce-Programme fehlte dieser Service bislang. Hier ist nun ein universelles Prüfziffernprogramm für den Joyce. Es erzeugt Prüfziffern für viele Programmiersprachen (Assembler, BASIC, Cobol usw.).
Die Prüfziffern (PZ) werden durch ein spezielles Verfahren ermittelt. Daher werden im Gegensatz zum Quersummenverfahren auch sog. »Zahlendreher« erkannt; Die Zeile '100 GOTO 1230' ergibt daher eine andere PZ als '100 GOTO 1320', obwohl die Quersummen gleich sind. Außerdem fallen nur zweistellige PZ an, um die Prüfung zu vereinfachen.
Texte nach dem vereinbarten REM-Zeichen (bzw. -Wort) werden nicht geprüft, können also weggelassen werden. Zeilennummern und Leerstellen im Programmtext fließen jedoch in die PZ ein. Um das Abtippen zu erleichtern, werden aufeinanderfolgende Leerstellen durch »...« (Punkte) ersetzt. Ausgenommen sind einzelne Leerstellen (bzw. die letzte Leerstelle einer Folge), um die Listings gut lesbar zu halten.
Das zu prüfende Programm wird ohne Prüfziffern, »...« (Punkte) als Leerstellen und mit Leerstelle hinter den REM-Zeichen erfaßt. Nach der Sicherung auf Disk A: wird es zusätzlich auf der Memory-Disk M: im ASCII-Format abgelegt. Der Programmname ist beliebig, die Erweiterung muß ».ASC« sein, z.B. SAVE "M:TEST.ASC",A.
Nach RUN"CHECK.BAS" beantworten Sie die Fragen nach Dateinamen, REM-Zeichen, Ausgabe, Zeilenlänge und Startzeile. Falls die in den spitzen Klammern < > vorgegebenen Werte beibehalten werden sollen, brauchen Sie nur mit der RETURN-Taste zu bestätigen.
Die Ausgabe kann auf dem Monitor <M>, dem Printer <P> oder in eine sequentielle Datei <D> erfolgen. Mit <f5> kann die Ausgabe angehalten bzw. fortgesetzt und mit <CAN> abgebrochen werden. Die bei der Ausgabe auf Disk erzeugte Datei (.PRN) kann ggf. mit RPED oder ED weiterverarbeitet werden. Auch mit LocoScript kann die Datei mit der Option »TEXT EINFÜGEN« gelesen werden, um z.B. Programmbeispiele mit PZ in Texte einzubinden. Das Programm wird durch Eingabe von »end« als Dateiname beendet.

(H.-J. Meyer)

Variablenliste der Datei 'm:check.bas'

   200          1060
   270           290
   380           410
   440           470
   500           530
   650           610
   690           650   710  1050
   730           740
   760           730
   860           880
   900           840
   930           950
   970           900
  1000          1020
  1040           970
  1060           690  1040
ausgabe$         160   380   390   420
bell$             60    80  1120
clen             770   770   790
datei$           160   250   270   280   310   560   570   590   630   670

datnam$          560   580
druck$           820   860   870   870   880   910   930   940   940   950
                 980  1000  1010  1010  1020
erste            520   530   530   710
esc$              60    70    70    80    80   180   180   620   620
fehl$             80   290   410   470   530
fehler$         1090  1100  1110  1120
in$              270   280   280   280   280   290   290   300   310   330
                 340   340   350   350   360   380   390   390   390   390
                 400   420   440   450   450   460   480   500   510   510
                 520   540
invoff$           70   230  1120
invon$            70   230  1120
prnnam$          570   660
rmk$             160   330   340   360   590   630   670   760   770
start$           160   500   510   540
suchdat$         240   250   250
summe            780   800   800   850   920   990
teil$            860   860   930   930  1000  1000
wahl             400   410   610   650   840   900   970
x                730   730   740   760   770   770   790   800   800
zeile$           700   710   730   740   760   770   800   820
zlen             460   470   470   860   870   930   940  1000  1010
zlen$            160   440   450   480

LISTING >CHECK   <, REMARK = >REM<.
<89> 10 REM check.bas 04.11.86 (C) H.J.Meyer Harsum
<78> 20 :
<55> 30 ON ERROR GOTO 1080
<80> 40 :
<85> 50 DEFINT c,s,w,x:DEFSNG e,z: WIDTH 90
<58> 60 bell$=CHR$(7):esc$=CHR$(27)
<69> 70 invon$=esc$+"p":invoff$=esc$+"q":REM invers an/aus
<23> 80 fehl$=bell$+esc$+"A"+esc$+"K"+CHR$(13):REM Zeile löschen
<85> 90 :
<97> 100 REM Voreinstellung
<83> 110 DATA END:.... REM Dateinane (bzw. end=Program beenden)
<26> 120 DATA REM:.... REM Remark is REM ( In Assembler= ; in Cobol = * usw.)
<22> 130 DATA M:...... REM Ausgabe (M=Monitor/P=Printer/D=Disk)
< 6> 140 DATA 40:..... REM Zeilenlänge (10-80)
<33> 150 DATA 0:...... REM Startzeile (0-65534)
<45> 160 READ datei$,rmk$,ausgabe$,zlen$,start$
<28> 170 :
<39> 180 PRINT esc$"H"esc$"E";
<32> 190 :
<39> 200 PRINT:PRINT CHR$(150)STRING$(35,154)CHR$(156)
<10> 210 PRINT CHR$(149)" J O Y C E - C H E C K S U M M E R "CHR$(149)
<83> 220 PRINT CHR$(147)STRING$(35,154)CHR$(153)
<22> 230 PRINT invon$:FILES "m:*.ASC":PRINT:PRINT invoff$
<58> 240 suchdat$=FIND$ ("M:*.asc")
<94> 250 IF suchdat$<>""THEN datei$=LEFT$(suchdat$,8)
<27> 260 :
<85> 270 PRINT"Dateiname","<"datei$">",:INPUT in$
<37> 280 in$=UPPER$(in$):IF in$="" THEN in$=datei$
<25> 290 IF VAL(in$)<>0 OR LEN(in$)>8 THEN PRINT fehl$;:GOTO 270
<35> 300 IF in$="END" THEN PRINT:END
<76> 310 datei$=in$
<20> 320 :
<78> 330 PRINT"REM-Zeichen","<"rmk$">",:INPUT in$
<84> 340 IF in$="" THEN in$=rmk$
<23> 350 IF in$="NO" THEN in$=CHR$(255)
<92> 360 rmk$=in$
<30> 370 :
<36> 380 PRINT"Ausgabe","<"ausgabe$">",:INPUT in$
<56> 390 in$=UPPER$(in$):IF in$="" THEN in$=ausgabe$
< 3> 400 wahl=INSTR("MPD",in$)
<22> 410 IF wahl=0 THEN PRINT fehl$;:GOTO 380
<37> 420 ausgabe$=in$
<23> 430 :
<89> 440 PRINT"Zeilenlänge","<"zlen$">",:INPUT in$
<35> 450 IF in$="" THEN in$=zlen$
<39> 460 zlen=VAL(in$)
<40> 470 IF zlen<10 OR zlen>80 THEN PRINT fehl$;:GOTO 440
<30> 480 zlen$=in$
<35> 490 :
<19> 500 PRINT"Startzeile","<"start$">",:INPUT in$
<81> 510 IF in$="" THEN in$=start$
<54> 520 erste=VAL(in$)
<50> 530 IF erste<0 OR erste>65534! THEN PRINT fehl$;:GOTO 500
<46> 540 start$=in$
<28> 550 :
<73> 560 datnam$="m:"+datei$+".ASC"
<30> 570 prnnam$="a:"+datei$+".PRN"
<35> 580 PRINT:OPEN"I",1,datnam$
<74> 590 PRINT"LISTING >"datei$"<, REMARK = >"rmk$"<.":PRINT
<19> 600 :
< 5> 610 IF wahl<>2 THEN 650
<50> 620 LPRINT esc$"l"CHR$(10);esc$"M";
<18> 630 LPRINT "LISTING >"datei$"<, REMARK = >"rmk$"<.":LPRINT
<27> 640 :
<16> 650 IF wahl<>3 THEN 690
<92> 660 OPEN"O",2,prnnam$
<30> 670 PRINT #2,"LISTING >";datei$;"<, REMARK = >";rmk$;"<.":PRINT #2," "
<35> 680 :
<45> 690 IF EOF(1) THEN GOTO 1060
<85> 700.. LINE INPUT #1,zeile$
< 0> 710.. IF VAL(zeile$)<erste THEN 690
<24> 720..:
<16> 730.. x=INSTR(zeile$,SPACE$(2)): IF x=0 THEN 760
<33> 740.. MID$(zeile$,x,1)=".":GOTO 730
<30> 750.. :
<13> 760.. x=INSTR(zeile$,rmk$+" ")
<44> 770.. IF x=0 THEN clen=LEN(zeile$):ELSE clen=x+LEN(rmk$)-1
<68> 780.. summe=0
<44> 790.. FOR x=1 TO clen
<85> 800.... summe=(summe+(ASC(MID$(zeile$,x,1))AND 127)*x)MOD 99
<70> 810.. NEXT
<67> 820.. druck$=zeile$
<27> 830.. :
<48> 840.. IF wahl<>1 THEN 900
<47> 850.. PRINT USING"<##> ";summe;
<50> 860.. teil$=LEFT$(druck$,zlen):PRINT teil$
<47> 870.. druck$=MID$(druck$,zlen+1)
<61> 880.. IF LEN(druck$)>0 THEN PRINT SPACE$(5);:GOTO 860
<39> 890.. :
<27> 900.. IF wahl<>2 THEN 970
<69> 910.. PRINT USING"< ##### >";VAL(druck$);
<77> 920.. LPRINT USING"<##> ";summe;
< 6> 930.. teil$=LEFT$(druck$,zlen):LPRINT teil$
<42> 940.. druck$=MID$(druck$,zlen+1)
<73> 950.. IF LEN(druck$)>0 THEN LPRINT SPACE$(5);:GOTO 930
<34> 960.. :
<63> 970.. IF wahl<>3 THEN 1040
<83> 980.. PRINT USING"< ##### >";VAL(druck$);
<83> 990.. PRINT #2,USING"<##> ";summe;
<67> 1000.. teil$=LEFT$(druck$,zlen):PRINT #2,teil$
<88> 1010.. druck$=MID$(druck$,zlen+1)
<18> 1020.. IF LEN(druck$)>0 THEN PRINT #2,SPACE$(5);:GOTO 1000
< 1> 1030.. :
<28> 1040.. IF INKEY$=CHR$(8) THEN GOTO 1060
<92> 1050 GOTO 690
<85> 1060 CLOSE:PRINT:GOTO 200
<20> 1070 :
<78> 1080 REM Fehlerbehandlung
<49> 1090 fehler$=" Fehler Nr."+STR$(ERR)+" in Zeile Nr."+STR$(ERL)+". "
<97> 1100 IF ERR=53 THEN fehler$=" Datei nicht vorhanden. "
<20> 1110 IF ERL=230 THEN fehler$=" Keine ASCII-Datei vorbanden. "
<71> 1120 CLOSE:PRINT invon$;fehler$;invoff$;bell$:PRINT
<64> 1130 IF ERL=230 THEN RESUME 270 ELSE RESUME 200

[Hier als BASIC- Quelle]