;Die folgenden Routinen zeigen verschiedene M|glich-
;keiten, die Betriebssystem-Routinen des JOYCE aufzu-
;rufen und zu nutzen.
;
;EQUATES  Definition der System-Adressen:
;
BIOS_USERF      EQU  0FC5AH
TE_RESET        EQU  00540H
TE_TXT_OUTPUT   EQU  00548H
TE_CUR_ENABLE   EQU  006ADH
TE_CUR_DISABLE  EQU  006B5H
TE_WRITE_CHAR   EQU  007A9H
ESC_H           EQU  00846H
ESC_Y           EQU  0084EH
TE_SET_LANGUAGE EQU  00912H
CR_Code         EQU  0000DH
LF_Code         EQU  0000AH
;
;Cursor }ber die Routine TE CUR DISABLE ausschalten
;
OFF_Cursor      CALL BIOS_USERF
                DEFW TE_CUR_DISABLE
;
;Cursor mit ESC H (Direkt-Einsprung) auf Position 0,0
;
Home_Cursor     CALL BIOS_USERF
                DEFW ESC_H
;
;Bildschirm }ber TE RESET l|schen
;
Clr_Screen      CALL BIOS_USERF
                DEFW TE_RESET
;
;kompletten Zeichensatz ausgeben, dabei die L{nder-
;spezifischen Zeichen wechseln
;
ZS_Out          LD   B,7
;
;Zeichensatz wechseln mit TE SET LANGUAGE
;
ZS_Change       LD   A,B
                PUSH BC
                CALL BIOS_USERF
                DEFW TE_SET_LANGUAGE
;
;mit TE WRITE CHAR alle Zeichen ausgeben
;
                XOR  A,A
L2_ZS_Out       LD   C,A
                PUSH AF
                CALL BIOS_USERF
                DEFW TE_WRITE_CHAR
                POP  AF
                INC  A
                JR   NZ,L2_ZS_Out
;
;CR/LF }ber TE TXT OUTPUT ausgeben
;
                LD   C,LF_Code
                CALL BIOS_USERF
                DEFW TE_TXT_OUTPUT
                LD   C,CR_Code
                CALL BIOS_USERF
                DEFW TE_TXT_OUTPUT
;
;
                POP  BC
                DJNZ ZS_Change
;
;wieder auf deutschen Zeichensatz (# 2) schalten
;
ZS_CH2          LD   A,2
                CALL BIOS_USERF
                DEFW TE_SET_LANGUAGE
;
;und Cursor mit TE ENABLE CURSOR einschalten
;
On_Cursor       CALL BIOS_USERF
                DEFW TE_CUR_ENABLE
;
;Programm mit Warm-Boot beenden
;
                JP   0
;
                END