Apfelmännchen in Pascal

Die sogenannte Mandelbrot-Menge (benannt nach ihrem Entdecker Benoit Mandelbrot) ist eine Teilmenge der komplexen Ebene.

Faßt man den Bildschirm als Ausschnitt aus einer Ebene auf und behandelt einen Punkt (x,y) dieser Ebene beim Rechnen als komplexe Zahl z = x + iy (i ist die ominöse imaginäre Einheit), dann kann man komplexe Zahlen als Punkte auf dem Bildschirm darstellen. Eine Mandelbrot-Menge, hier das Apfelmännchen, entsteht, wenn man die durch Iteration definierte Folge

z(0) = c; z(n+1) = z(n)² + c

für komplexe c untersucht und danach fragt, ob sie konvergiert oder divergiert (im Programm beschränkt sich das auf die Frage, ob ein bestimmter Betrag von den Folgengliedern überschritten wird oder nicht).

Da wir natürlich nicht beliebig lange rechnen können, um das Verhalten eines Punktes c zu testen, müssen wir nach einer festgesetzten Anzahl von Schleifendurchläufen (bzw. wenn der Betrag des Ergebnisses einen Maximalwert übersteigt) abbrechen. Der Autor hat hierfür jeweils den etwas willkürlichen Wert 100 gewählt.

Das Programm setzt die Turbo-Pascal-Grafik-Routinen aus mc 85, Heft 4 [Dieser Artikel steht leider nicht zur Verfügung] voraus und verwendet nur 230 der 280 möglichen vertikalen Bildpunkte, um eine Verzerrung der Figur zu vermeiden. Ersetzt man die IF-Zeile durch die in (* *) geklammerte Zeile, so wird nicht nur das Apfelmännchen gezeichnet, sondern noch zusätzlich seine Umgebung nach verschiedener Divergenzgeschwindigkeit strukturiert (Farbe wäre hier eine wertvolle Bereicherung). Nach Abschluß der Berechnungen steht das Bild, bis eine beliebige Taste gedrückt wird.

Sollten komplexe Zahlen, Divergenz, Konvergenz usw. ein Buch mit sieben Siegeln für Sie sein, vergessen Sie die ganze Mathematik und genießen Sie einfach den eigenen Reiz des Apfelmännchens.

Abschließend sei noch darauf hingewiesen, daß es sich durchaus lohnt, Ausschnittsvergrößerungen des Mengenrandes anzufertigen, wobei zu beachten ist, daß dann die Abbruchbedingungen nach oben zu erweitern sind. Dies kann durchaus eine erhebliche Steigerung der momentanen Rechenzeit von ca. 4,5 Stunden auf dem Apple nach sich ziehen (Achtung: Symmetrie der Rekursion bzgl. + Im (c) und - Im (c), d.h. Halbierung der Laufzeit).

PROGRAM MANDELBROT ( OUTPUT );

(*$I GR.PAS *)

VAR  X, Y, X_ALT, Y_ALT, RE_C, IM_C, DC : REAL;
     K, L, N : INTEGER;

BEGIN
  GRAPHIC;
  COLOR ( WHITE );
  DC := 3 / 230;
  FOR K := 0 TO 230 DO
    BEGIN
      RE_C := -2.25 + K * DC;
      FOR L := 0 TO 95 DO
        BEGIN
          IM_C := L * DC;
          X := 0;  Y := 0;
          N := 0;
          REPEAT
            X_ALT := X;  Y_ALT := Y;
            X := SQR( X_ALT ) - SQR ( Y_ALT ) + RE_C;
            Y := 2 * X_ALT * Y_ALT + IM_C;
            N := N + 1;
          UNTIL ( N > 100 ) OR ( ( SQR( X ) + SQR( Y ) ) > 100 );
          IF ( N > 100 ) THEN
(* IF ( N > 100 ) OR ( ( N < 11 ) AND ( N MOD 2 = 0 ) ) THEN *)
                         BEGIN
                           PLOT ( K, 95 + L );
                           PLOT ( K, 95 - L )
                         END
        END
    END;
   WHILE NOT KEYPRESSED DO;
END.

Bild 1. Das Programm in Pascal

Especially for the JOYCE: The program. Including the driver (extracted from the articlel, found here).

[Durch Anklicken der Bilder erscheinen die vom Joyce erzeugten Ausgaben mit dem geänderten Programm.]

Bild 2. Interessant ist das Gebiet mit -2,25 ≤ Re(c) ≤ 0,75 und -1,25 ≤ Im(c) ≤ 1,25

Bild 3. Rund ums Apfelmännchen gibt es Interessantes zu beobachten