Ein 'CAT'-Befehl für CP/M

Ein 'CAT'-Befehl für CP/M

"Warum ein CAT, wenn es schon ein DIR gibt?" werden Sie sich sicher fragen, und den Griff zur nächsten Seite tun wollen. Doch bevor Sie diese Aktion starten, lesen Sie lieber doch erst einmal den Text, zumal dies auch für Besitzer eines JOYCE interessant sein dürfte.

Der CP/M-Befehl 'DIR' ist zwar ganz nützlich, wenn man sich über die Programme und Dateien auf seiner Arbeitsdiskette informieren will, wer aber viele Dateien darauf hat, sucht in dem Directory eine ganze Weile, bis er 'sein' Programm gefunden hat. Hier würde sich ein Diskkatalog gut machen, der die Files in alphabetischer Reihenfolge auf den Bildschirm bringt. Nun, "CAT.COM" ist so ein Katalogprogramm, und ist durch seine Kürze von einem Kilobyte auch auf (fast) jeder Diskette noch unterzubringen, sofern sie zur Gruppe der CP/M-Disketten gehört. Nachdem Sie nun also 'CAT' eingegeben haben, wird das sortierte Inhaltsverzeichnis der Diskette sowie noch einige Zusatzinformationen über die Programme ausgegeben.
So werden R/O-Files am Ende des Dateinamens mit einem Stern '*' versehen, SYS-Files, die normalerweise nicht angezeigt werden, bekommen ein Plus '+' als Kennzeichen, und falls jemand Programme auf seinen Disketten hat, die sowohl nur lesbar, als auch versteckt sind, der erkennt sie im Inhaltsverzeichnis daran, daß sie am Ende mit einer schließenden Klammer ')' gekennzeichnet sind.

Natürlich können Sie, wie bei 'DIR' auch, Wildcards benutzen, also Füllzeichen, wie zum Beispiel bei CAT *.COM, welches Ihnen nur alle COM-Files auflistet.

Da das Programm nur normale CP/M 2.2 BDOS-Aufrufe benutzt, läuft es auf allen CPC-Rechnern. Sie müssen dazu nur den Lader eintippen und mit RUN starten, das Programm legt danach das File CAT.COM auf Ihre Diskette ab. Damit aber nicht genug, auch JOYCE-Besitzer können dieses Programm benutzen. Zwar kann der JOYCE mit dem Lader nichts anfangen, dafür haben wir aber das komplette Assemblerfile abgedruckt, so daß diese Computerfreunde sich daran versuchen können. Auf der DATABOX befindet sich dazu das fertige COM-File, das auf allen Rechnern läuft.

(Ralf Wegener/jb)

10 OPENOUT "cat.com"                       [1051]
20 dat=0:sz=0:dz=140                       [326]
30 FOR adr=&100 TO &263	                   [1004]
40 READ byte$:byte=VAL("&"+byte$):dat=dat+ [2593]
1
50 sz=sz+byte                              [619]
60 PRINT#9,CHR$(byte);                     [977]
70 IF dat<16 AND adr<&263 THEN 110         [563]
80 READ chksum                             [1222]
90 IF chksum<>sz THEN PRINT"Fehler in Zeil [3056]
e :";dz
100 dz=dz+10:sz=0:dat=0                    [843]
110 NEXT adr                               [547]
120 CLOSEOUT                               [902]
130 END                                    [110]
140 DATA ED,73,67,02,31,89,02,AF,32,7C,00, [2533]
32,64,02,21,5D, 1272
150 DATA 00,3E,20,BE,20,07,06,0B,36,3F,23, [2841]
10,FB,1E,FF,0E, 1058
160 DATA 20,CD,05,00,32,63,02,21,89,02,E5, [2922]
0E,11,11,5C,00, 934
170 DATA CD,05,00,FE,FF,28,5D,18,09,0E,12, [1995]
CD,05,00,FE,FF, 1636
180 DATA 28,52,0F,0F,0F,21,80,00,06,00,4F, [3317]
09,3A,63,02,BE, 771
190 DATA 20,E7,23,EB,E1,36,3A,23,36,20,23, [2257]
36,20,23,06,08, 1161
200 DATA 1A,E6,7F,77,23,13,10,F8,36,2E,23, [3219]
06,03,1A,CB,27, 1232
210 DATA CB,11,1A,E6,7F,77,23,13,10,F3,36, [3304]
20,79,CB,3F,28, 1548
220 DATA 05,ED,44,C6,2C,77,23,36,20,23,36, [3107]
24,23,E5,21,64, 1314
230 DATA 02,34,18,A5,E1,22,65,02,21,64,02, [1568]
7E,B7,CA,4E,02, 1331
240 DATA FE,01,28,41,4F,21,7A,02,0D,7D,C6, [2509]
12,6F,7C,CE,00, 1391
250 DATA 67,41,54,5D,7B,C6,12,5F,7A,CE,00, [2907]
57,C5,D5,E5,1A, 1859
260 DATA CB,BF,4E,CB,B9,B9,38,06,20,13,13, [3026]
23,18,F1,E1,D1, 1911
270 DATA D5,E5,06,0F,1A,4E,EB,71,12,23,13, [3734]
10,F7,E1,D1,C1, 1877
280 DATA 10,D2,0D,20,C4,2A,65,02,11,12,00, [2580]
36,24,19,36,24, 852
290 DATA 19,36,24,3A,64,02,4F,CB,39,CB,39, [3140]
E6,03,28,01,0C, 1160
300 DATA 06,00,3A,5C,00,C6,41,CD,3F,02,AF, [2493]
1E,04,F5,C5,D5, 1553
310 DATA 80,5F,3E,00,17,57,21,89,02,06,12, [2881]
19,10,FD,EB,0E, 1134
320 DATA 09,CD,05,00,D1,C1,F1,81,10,20,E2, [2057]
F5,3E,0D,CD,3F, 1866
330 DATA 02,3E,0A,CD,3F,02,F1,04,79,B8,C2, [3145]
02,02,18,17,C5, 1336
340 DATA D5,E5,E6,7F,5F,0E,02,CD,05,00,E1, [3315]
D1,C1,C9,11,5B, 2056
350 DATA 02,0E,09,CD,05,00,ED,7B,67,02,C9, [3041]
4E,4F,20,46,49, 1233
360 DATA 4C,45,24,00, 181                  [1216]

[CPC-Listing] oder [PCW-Listing]

   10         org     0100h
   20 bdos    equ     5
   30 fcb     equ     005ch           ; Standardadr FCB
   40 dma     equ     0080h           ; Standardadr. DMA
   50 LF      equ     10              ; LineFeed
   60 CR      equ     13              ; CarriageReturn
   70 conout  equ     2               ; CONSOLE OUTPUT
   80 strout  equ     9               ; PRINT STRING
   90 sfirst  equ     17              ; SEARCH FOR FIRST
  100 snext   equ     18              ; SERACH FOR HEXT
  110 getus   equ     32              ; SET/GET USER CODE
  120 ;
  130 start:  ld      (ostack),sp     ; alter Stack
  140         ld      sp,stktop       ; neuer Stack
  150         xor     a
  160         ld      (fcb+32),a
  170         ld      (anz),a         ; Fileanz. auf Null
  180         ld      hl,fcb+1        ; falls kein
  190         ld      a," "           ; Parameter,
  200         cp      (hl)            ; dann
  210         jr      nz,weiter
  220         ld      b,11            ; *.*
  230 wild:   ld      (hl),"?"        ; als Name
  240         inc     hl              ; in FCB
  250         djnz    wild            ; eintragen
  260 weiter: ld      e,255
  270         ld      c,getus
  280         call    bdos            ; USER holen
  290         ld      (user),a        ; und merken
  300         ld      hl,puff         ; Zieladr. File
  310         push    hl              ; merken
  320         ld      c,sfirst
  330         ld      de,fcb
  340         call    bdos            ; search first
  350         cp      0ffh            ; schon letzter
  360         jr      z,sort          ; ja, sortieren
  370         jr      copy            ; sonst =>
  380 next1:  ld      c,snext
  390         call    bdos            ; search next
  400         cp      0ffh            ; letzter ?
  410         jr      z,sort          ; ja, sortieren
  420 ;
  430 ; Name aus FCB in Puffer
  440 ; eintragen und formatieren
  450 copy:   rrca
  460         rrca
  470         rrca                    ; a=a*32
  480         ld      hl,dma          ; Adr. DMA
  490         ld      b,0
  500         ld      c,a             ; bc=Offstet
  510         add     hl,bc           ; tats. Adr.
  520         ld      a,(user)        ; USER holen
  530         cp      (hl)            ; korrekt ?
  540         jr      nz,next1        ; nein, neuer Eintrag
  550         inc     hl              ; USER-Nr. nicht kopieren
  560         ex      de,hl           ; de=quelle
  570         pop     hl
  580         ld      (hl),":"        ; Trennz. zwischen Namen
  590         inc     hl              ; Zeiger erhoehen
  600         ld      (hl)," "
  610         inc     hl
  620         ld      (hl)," "
  630         inc     hl
  640         ld      b,8             ; 8 Zeichen Name
  650 nam:    ld      a,(de)          ; Zeichen aus FCB
  660         and     127
  670         ld      (hl),a          ; in den Puffer
  680         inc     hl
  690         inc     de
  700         djnz    nam
  710         ld      (hl),"."        ; Trennz. Name_Ext
  720         inc     hl
  730         ld      b,3             ; 3 Zeichen Extension
  740 ext:    ld      a,(de)          ; Zeichen aus FCB
  750         sla     a               ; Attribut
  760         rl      c               ; nach c
  770         ld      a,(de)          ; nochmal holen
  780         and     127
  790         ld      (hl),a          ; in den Puffer
  800         inc     hl
  810         inc     de
  820         djnz    ext
  830         ld      (hl)," "        ; Default Attributkennz.
  840         ld      a,c
  850         srl     a
  860         jr      z,noattr        ; falls kein Attribut =>
  870         neg                     ; Attributkennz.
  880         add     a,","           ; berechnen
  890         ld      (hl),a          ; und in den Puffer
  900 noattr: inc     hl
  910         ld      (hl)," "
  920         inc     hl
  930         ld      (hl),"$"        ; Kennz. Stringende
  940         inc     hl
  950         push    hl
  960         ld      hl,anz
  970         inc     (hl)
  980         jr      next1
  990 sort:   pop     hl              ; Adr. letzter Eintr.
 1000         ld      (last),hl       ; merken
 1010         ld      hl,anz
 1020         ld      a,(hl)          ; Gesamtanz. holen
 1030         or      a               ; a=0?
 1040         jp      z,nofile        ; ja, =>
 1050         cp      1               ; a=1?
 1060         jr      z,print         ; ja, gleich ausgeben
 1070         ld      c,a             ; sonst sortieren
 1080 ;
 1090 ; SORT
 1100 ;
 1110         ld      hl,puff-15
 1120         dec     c
 1130 nexte:  ld      a,l             ;
 1140         add     a,18            ;
 1150         ld      l,a             ;
 1160         ld      a,h             ;
 1170         adc     a,0             ;
 1180         ld      h,a             ; hl=hl+18
 1190         ld      b,c
 1200         ld      d,h             ;
 1210         ld      e,l             ; de=hl
 1220 nextb:  ld      a,e             ;
 1230         add     a,18            ;
 1240         ld      e,a             ;
 1250         ld      a,d             ;
 1260         adc     a,0             ;
 1270         ld      d,a             ; de=de+18
 1280 ;
 1290 ; (DE)<(HL)?
 1300 ;
 1310         push    bc
 1320         push    de
 1330         push    hl
 1340 next2:  ld      a,(de)          ; Zeichen holen
 1350         res     7,a
 1360         ld      c,(hl)          ; Zeichen holen
 1370         res     7,c
 1380         cp      c               ; vergleichen
 1390         jr      c,tausch        ; c>a, tauschen
 1400         jr      nz,exit         ; c<a, nicht tauschen
 1410         inc     de              ; c=a, naechstes Zeichen
 1420         inc     hl
 1430         jr      next2
 1440 ;
 1450 ; TAUSCH
 1460 ;
 1470 tausch: pop     hl
 1480         pop     de
 1490         push    de
 1500         push    hl
 1510         ld      b,15            ; 15 Zeichen tauschen
 1520 next3:  ld      a,(de)
 1530         ld      c,(hl)
 1540         ex      de,hl
 1550         ld      (hl),c
 1560         ld      (de),a
 1570         inc     hl
 1580         inc     de
 1590         djnz    next3
 1600 ;
 1610 exit:   pop     hl
 1620         pop     de
 1630         pop     bc
 1640         djnz    nextb
 1650         dec     c
 1660         jr      nz,nexte        ; bis alles sortiert
 1670 ;
 1680 print:  ld      hl,(last)       ; drei
 1690         ld      de,18           ; Leerstrings
 1700         ld      (hl),"$"        ; am
 1710         add     hl,de           ; Ende
 1720         ld      (hl),"$"        ; des
 1730         add     hl,de           ; Puffers
 1740         ld      (hl),"$"        ; eintragen
 1750         ld      a,(anz)
 1760         ld      c,a
 1770         srl     c
 1780         srl     c               ; c=c div 4
 1790         and     3               ; a=a mod 4
 1800         jr      z,teilb
 1810         inc     c
 1820 teilb:  ld      b,0             ; c=Anzahl Zeilen
 1830 zeile:  ld      a,(fcb)         ; Drive holen
 1840         add     a,"A"           ; Offset addieren
 1850         call    out             ; ausgeben
 1860         xor     a
 1870         ld      e,4             ; 4 Spalten
 1880 spalte: push    af
 1890         push    bc
 1900         push    de
 1910         add     a,b             ;
 1920         ld      e,a             ;
 1930         ld      a,0             ;
 1940         rla                     ;
 1950         ld      d,a             ; de=b+a
 1960         ld      hl,puff
 1970         ld      b,18
 1980 addi:   add     hl,de
 1990         djnz    addi            ; hl=(b+a)*18+puff
 2000         ex      de,hl
 2010         ld      c,strout
 2020         call    bdos
 2030         pop     de
 2040         pop     bc
 2050         pop     af
 2060         add     a,c
 2070         dec     e               ; e=Spaltenzaehler
 2080         jr      nz,spalte
 2090         push    af              ; am
 2100         ld      a,CR            ; Ende
 2110         call    out             ; der Zeile
 2120         ld      a,LF            ; CR und
 2130         call    out             ; LF aus-
 2140         pop     af              ; geben
 2150         inc     b               ; naechste Zeile
 2160         ld      a,c
 2170         cp      b               ; schon letzte?
 2180         jp      nz,zeile        ; nein, weiter
 2190         jr      ende            ; sonst alles fertig
 2200 ;
 2210 out:    push    bc              ; Zeichen in a ausg.
 2220         push    de
 2230         push    hl
 2240         and     127
 2250         ld      e,a
 2260         ld      c,conout
 2270         call    bdos
 2280         pop     hl
 2290         pop     de
 2300         pop     bc
 2310         ret
 2320 ;
 2330 nofile: ld      de,nostr        ; 'NO FILE' ausgeben
 2340         ld      c,strout
 2350         call    bdos
 2360 ende:   ld      sp,(ostack)     ; CCP-Stack holen
 2370         ret                     ; zurueck zum CCP
 2380 ;
 2390 nostr:  defm    "NO FILE$"
 2400 user:   defb    0
 2410 anz:    defb    0
 2420 last:   defw    0
 2430 ostack: defw    0
 2440         defs    32              ; Platz fuer 16 Eintr
 2450 stktop: defs    0
 2460 puff:   defs    0

[Listing]

Eingescanned von Werner Cirsovius
Dezember 2002

Neues vom Directory

Ein 'CAT'-Befehl für CP/M

"Warum ein CAT, wenn es schon ein DIR gibt?" werden Sie sich sicher fragen, und den Griff zur nächsten Seite tun wollen. Doch bevor Sie diese Aktion starten, lesen Sie lieber doch erst einmal den Text, zumal dies auch für Besitzer eines JOYCE interessant sein dürfte.