In der „PC AMSTRAD INTERNATIONAL 12'91/1'92" wurde der folgende Artikel abgedruckt.

Das Spiel Bounce in BASIC.

Bounce

100 Level Spielvergnügen

BOUNCE!! Ist es nicht das, was Sie schon immer für Ihren PCW gesucht haben? Ein Spiel, das Sie nicht mehr losläßt, sobald Sie es einmal begonnen haben? Nun, vor Ihnen liegt es. BOUNCE erfordert logische Vorgehensweise, stellt Anforderungen an Ihre Geschicklichkeit und verlangt zudem starke Nerven. Das Programm zeichnet sich durch Pulldown-Menüs, akustische und grafische Effekte aus, aber sehen Sie selbst und lassen Sie sich überraschen:

Auf einem acht x acht grossen Feld befinden sich Spielsteine, deren Position einer bestimmten Gesetzmässigkeit unterliegen. Diese sind von einem vorgegebenen Startstein beginnend durch Springen auf einen anderen Stein zu vernichten. Dabei gibt es acht verschiedene Sprungmöglichkeiten: Mit den vier Cursor-Tasten alleine können einfache Sprünge, in Verbindung mit der SHIFT-Taste jedoch Doppelsprünge in horizontaler und vertikaler Richtung ausgeführt werden. Der jeweils verlassene Stein wird vernichtet. Ihre Aufgabe ist es, in hundert Sekunden das gesamte Spielfeld abzuräumen. Das Limit wird im Info-Fenster und als schrumpfender Balken links neben dem Spielfeld angezeigt. Sollte das Limit bis auf dreißig Sekunden ablaufen, so fängt die gesamte Bildschirmdarstellung an zu wackeln. Verstreicht das Limit oder haben Sie sich versprungen, so ist das Spiel verloren.

Die auf Diskette vorhandenen Level werden nach einem Zufallssystem ausgesucht, jedoch so, daß sich die Level erst dann wiederholen, wenn alle vorhandenen gespielt worden sind. In diesem Fall jedoch werden diese in anderer Form als zuvor dargestellt (andere Startposition (2), spiegelverkehrt (2), gedreht (4)). Die Zahlen in Klammern geben die Anzahl der Möglichkeiten an. Insgesamt kann also jeder Level in 2x2x4=16 Variationen auftreten.

Während des Spiels wandeln sich gelegentlich normale Spielsteine in die Buchstaben b,o,u,n,c,e um, die für zehn Sekunden stehen bleiben. Gelingt es Ihnen, in dieser Zeit den aufgetauchten Buchstaben zu vernichten, so gibt es Extrapunkte, andernfalls wandelt sich der Buchstabe wieder in einen normalen Spielstein um.

Sollten Sie einmal alle sechs verschiedenen Buchstaben vernichtet haben, so daß das Wort "bounce" komplett ist, so gibt es nochmals Extrapunkte. Die Anzahl der durch Sie vernichteten Buchstaben wird im Infofenster angezeigt. Mit STOP können Sie während des Spiels eine Pause einlegen. Dabei wird das Spielfeld gelöscht, die Pause angezeigt und das Spiellimit angehalten. Bereits erschienene, nicht vernichtete Buchstaben gehen verloren. Wollen Sie das Spiel fortsetzen, so drücken Sie eine beliebige Taste. Das Drücken der PTR-Taste während des Spiels hat keinen Einfluss auf das Limit!

Sollten Sie bis spät in die Nacht spielen und möchten dabei niemand stören, so können Sie mit AUSBL alle akustischen Signale aus- und auch wieder einschalten.

Wenn Ihnen während des Spiels ein Level auffallen sollte, den Sie vielleicht anschließend bearbeiten möchten, so drücken Sie COPY, damit sich BOUNCE diesen Level merkt. Wie unten beschrieben, können Sie diesen dann im Editor durch erneutes Drücken von COPY aufrufen.

Die Highscore-Liste

BOUNCE verfügt über eine Highscore-Liste, in die Sie BOUNCE automatisch eintragen läßt, wenn Sie mit Ihren erspielten Punkten einen der ersten zehn Plätze belegen. Diese Highscore-Liste wird auf Diskette abgespeichert. Existiert diese bei Programmstart nicht auf Diskette, so wird eine Liste erstellt, in der alle zehn Plätze mit zu überbietenden Punkten belegt sind. Die aktuelle Highscore-Liste können Sie sich jederzeit im Hauptmenü zeigen lassen. Abgespeichert werden dabei Ihr Name, Ihre erzielten Punkte, der erreichte Level, die Anzahl der durch Sie vernichteten Buchstaben und die gesamte Spieldauer in Sekunden. Bei Punktgleichheit entscheidet die Anzahl gespielter Level, dann die Anzahl vernichteter Buchstaben, dann die kürzere Spieldauer und letztendlich das neuere Ergebnis über die bessere Platzierung.

Erstellen Sie sich Ihre eigenen Level

Der Editor

BOUNCE enthält einen Editor, mit dem Sie eigene Level erstellen und auf Diskette abspeichern können. Wenn Sie ihn im Hauptmenü aufrufen, so wird Ihnen im Info-Fenster in Klammern angezeigt, wieviele Level bereits existieren. Sie werden nun gefragt, ob Sie einen Level aufrufen oder erstellen wollen. Im ersten Fall springt der Cursor ins Infofenster und erwartet die Eingabe des gewünschten Levels. Drücken Sie ENTER, ohne eine Eingabe gemacht zu haben, so ruft BOUNCE den zuletzt aufgerufenen beziehungsweise. bearbeiteten auf. Wenn Sie COPY drücken, ruft BOUNCE automatisch den durch Sie während des Spiels markierten Level auf. Haben Sie jedoch zuvor keinen Level aufgerufen oder markiert oder haben Sie einen Level gelöscht, so wird der erste Level aufgerufen.

Durch Drücken der Taste zwischen den Cursor-Tasten setzen Sie einen Stein oder löschen einen bereits gesetzten. Mit FORM bestimmen Sie eine Startposition oder löschen eine bereits bestimmte. Pro Level müssen zwei Startpositionen angegeben werden.

Wenn Sie einen Level ordnungsgemäß mit zwei Startpositionen erstellt haben, so drücken Sie ENTER, damit BOUNCE Sie fragen kann, ob der Level in dieser Form abgespeichert werden kann. Das Programm schließt nach einem Schreibzugriff die betroffene Datei und öffnet sie wieder, damit zu jeder Zeit die Daten gesichert sind. Mit CAN brechen Sie fast jede gewählte Operation ab.

Zum Listing BOUNCE.BAS: Um das Programm BOUNCE lauffähig zu machen, ist die Tastaturbelegung geringfügig zu ändern: Hierfür erstellen Sie mit dem Programm RPED.BAS die Datei BOUNCE.WP

07 N "^'251'" <RETURN>
14 S "^'252'" <RETURN>
79 S "^'253'" <RETURN>
15 S "^'254'" <RETURN>
06 S "^'255'" <RETURN>

Diese Änderung1 ist notwendig, um SHIFT-Cursor - Kombinationen und die Benutzung der Taste zwischen den Cursor-Tasten zu ermöglichen. Vor dem Programmstart müssen Sie dann unter CP/M mit dem Programm SETKEYS.COM (Seite zwei der Systemdisketten) die Tastatur mit der Eingabe "SETKEYS BOUNCE.WP" umdefinieren und das Spiel mit "BASIC BOUNCE" starten.

Zum Listing LEVEL.BAS: Dieses Listing enthält hundert ausgeklügelte und getestete Level für BOUNCE, das nach dem Programmstart die Datei BOUNCE.LEV eröffnet und alle Level spielfertig einrichtet. Jeweils fünf DATA-Werte ergeben einen Level.

Hannes Geyer/rs

In letzter Minute konnte noch ein Fehler im Programm ausfindig gemacht werden, der sich auf die Berechnung der Extrabounspunkte auswirkt. Um diesen Fehler zu korrigieren, ändern Sie einfach die folgenden drei Zeilen wie angegeben ab:


1130 ge=1:bw=INT(6*RND):s=8*xw-4:FOR z=4*yw-4 TO 4*yw-2:GOSUB 90:PRINT SPC(6):NEXT z:z=4*yw-1:FOR i=1 TO 3:z=z-1:GOSUB90:PRINT inv$;MID$(bou$,8*bw+1+(z-4*yw+4)*48,6);nrm$:NEXT i:zv=se


1370 ge=0:bon=bon+1:GOSUB 2670:GOSUB 2960:pun=pun+(2*lim MOD 10):ep1=INT(2*lim/10):ep2=10:gosub 2870:IF (gbs AND 2^bw)=0 THEN gbs=gbs+2^bw


1385 GOSUB 3020

Auf der DATABOX steht selbstverständlich die korrigierte Fassung von BOUNCE zur Verfügung.

LISTING >BOUNCE<, REMARK = >'<.
 
<67> 10 '*****************************************
     *****
<22> 20 '*.............. BOUNCE.. V 1.4...........
     ... *
< 5> 30 '* (C) 23.08.1991 by Hannes Geyer, 4300 Es
     sen *
<96> 40 '*... f}r PCW 8256/8512 - Schneider JOYCE.
     ... *
<63> 50 '*.. Mallard BASIC...... 18 Total 1k Block
     s.. *
<72> 60 '*****************************************
     *****
<26> 70 OPTION RUN:CLEAR ,,,2,35
<15> 80 DEFINT a-o,q-z:WIDTH 255:GOTO 100
<61> 90 PRINT esc$;"Y";CHR$(z+32);CHR$(s+32);:RETU
     RN
< 0> 100 DIM men$(6,4),ste$(3),jn(25),mo(6),fe(8,8
     ),v(6),b1(15),b2(15),zm(16),mt(16),bex(2),bey
     (2)
<46> 110 esc$=CHR$(27):clr$=esc$+"E"+esc$+"H"
<23> 120 inv$=esc$+"p":nrm$=esc$+"q"
<41> 130 uns$=esc$+"f":sic$=esc$+"e"
<95> 140 und$=esc$+"r":nun$=esc$+"u"
<82> 150 he$=esc$+"b"+CHR$(63)+esc$+"c"+CHR$(0)
<96> 160 du$=esc$+"b"+CHR$(0)+esc$+"c"+CHR$(63)
<58> 170 so$=" ON":so1$="OFF":lem=1:lds=1:tw=11:tw
     1=12:w1=255:w2=0:u1=255:u2=0
<88> 180 men$(1,1)=" BOUNCE starten.. ":men$(1,2)=
     " Highscore-Liste. ":men$(1,3)=" Editor aufru
     fen. ":men$(1,4)=" BOUNCE Ende..... "
<87> 190 men$(2,1)=" Level erstellen. ":men$(2,2)=
     " Level aufrufen.. ":men$(2,3)=" Editieren En
     de.. "
< 2> 200 men$(3,1)=" Level speichern. ":men$(3,2)=
     " Level unkorrekt. ":men$(3,3)=" Abbrechen...
     .... "
<65> 210 men$(4,1)=" Level bearbeiten ":men$(4,2)=
     " Level l|schen... ":men$(4,3)=men$(3,3)
<87> 220 men$(5,1)=" Best{tigen...... ":men$(5,2)=
     men$(3,3)
<10> 230 men$(6,1)=" -> Mallard BASIC ":men$(6,2)=
     " -> CP/M......... ":men$(6,3)=" -> Modus 24 
     x 80 ":men$(6,4)=" -> Systemstart.. "
<13> 240 lo$=CHR$(134):ro$=CHR$(140):lu$=CHR$(131)
     :ru$=CHR$(137):ve$=CHR$(133):ho$=STRING$(18,1
     38)
<54> 250 ste$(1)=lo$+STRING$(4,138)+ro$:ste$(2)=ve
     $+"... "+ve$:ste$(3)=lu$+STRING$(4,138)+ru$
<39> 260 a$=STRING$(4,154):b$=CHR$(149)+"... "+CHR
     $(149)+". ":c$=CHR$(150)+a$+CHR$(156)+". ":d$
     =CHR$(147)+a$+CHR$(153)+". "
<22> 270 bou$=CHR$(148)+SPACE$(7)+c$+CHR$(148)+"..
     . "+CHR$(148)+". "+c$+c$+c$+CHR$(151)+RIGHT$(
     c$,7)+b$+b$+b$+CHR$(149)+SPACE$(7)+CHR$(151)+
     RIGHT$(d$,7)+d$+d$+d$+CHR$(145)+"... "+CHR$(1
     45)+". "+d$+LEFT$(d$,5)+CHR$(152)+". "
< 9> 280 FOR i=1 TO 6:mo(i)=i:NEXT i
<64> 290 pa$=inv$+". "+nrm$:pa$(1)=pa$+pa$+pa$:pa$
     (2)=pa$+". "+pa$:pa$(3)=pa$:pa$(4)="... "+pa$
<23> 300 cue$=" "+CHR$(149)+CHR$(146)+CHR$(152)+CH
     R$(149)+" "
<53> 310 FOR i=1 TO 8:eli$=eli$+".. "+CHR$(146)+CH
     R$(152)+".. ":NEXT i
<73> 320 nor$=esc$+"X. ?y":lf1$=esc$+"X #>_"+clr$+
     nor$:lf2$=esc$+"X-f13"+clr$+nor$:lf3$=esc$+"X
     &n$*"+clr$+nor$:lf4$=esc$+"X. > "+clr$+nor$
<40> 330 ba=16:FOR i=1 TO 15:READ b1(i),b2(i):NEXT
      i
<83> 340 FOR i=1 TO 25:READ jn(i):NEXT i
<42> 350 DATA 128,144,145,148,146,152,139,142,149,
     133,211,47,135,141,150,153,60,62,138,154,138,
     32,149,32,131,140,220,221,240,244,1,2,1,3,3,1
     ,2,1,2,2,2,2,2,2,1,1,3,1,4,1,1,3,1,3,1
< 8> 360 RANDOMIZE (PEEK(&HFBF7)+1)*(PEEK(&HFBF8)+
     1)
<90> 370 PRINT du$;uns$;nrm$;nor$;clr$;
<36> 380 '
<23> 390 '***** Bildschirmaufbau *****************
     *****
<21> 400 '
<94> 410 OUT 248,8:OUT 245,91:OUT 246,115:GOSUB 29
     50
<76> 420 h1=141:h2=115:OUT 248,7:FOR i=1 TO 114:h1
     =h1+1:h2=h2-1:OUT 246,h1:FOR j=1 TO 30:NEXT j
     :OUT 246,h2:FOR j=1 TO 30:NEXT j:IF INKEY$=""
      THEN NEXT i ELSE ub=1
<36> 430 OUT 246,0:r1=SGN(0.5-INT(2*RND)):r2=SGN(0
     .5-INT(2*RND)):FOR i=0 TO 30:z=r1*(i-15)+15:s
     =1:GOSUB 90:PRINT inv$;CHR$(149):z=r2*(i-15)+
     15:s=68:GOSUB 90:PRINT CHR$(149);nrm$:NEXT i
<49> 440 z=0:s=70:GOSUB 90:PRINT lo$;ho$;ro$
<62> 450 FOR z=1 TO 3:GOSUB 90:PRINT ve$;SPC(18);v
     e$:NEXT z
<64> 460 z=4:GOSUB 90:PRINT lu$;ho$;ru$:z=5:GOSUB 
     90:PRINT lo$;ho$;ro$
<98> 470 FOR z=6 TO 11:GOSUB 90:PRINT ve$;SPC(18);
     ve$:NEXT z
<26> 480 z=12:GOSUB 90:PRINT lu$;ho$;ru$
<78> 490 z=2:s=73:GOSUB 90:PRINT "BOUNCE.. V 1.4":
     z=6:s=72:GOSUB 90:PRINT "Score:":z=7:GOSUB 90
     :PRINT "Level:":z=8:GOSUB 90:PRINT "Bonus:":z
     =9:GOSUB 90:PRINT "Limit:":z=10:GOSUB 90:PRIN
     T "Dauer:":z=11:GOSUB 90:PRINT "Sound:.......
      ON"
<33> 500 IF ub=1 THEN 590
<74> 510 FOR u=1 TO 4:FOR i=6 TO 1 STEP -1:SWAP mo
     (INT(i*RND)+1),mo(i):f=mo(i)
<86> 520 s=8*f+4:FOR z=14 TO 16:GOSUB 90:PRINT SPC
     (6):NEXT z:FOR z=16 TO 14 STEP -1:GOSUB 90
<81> 530 IF u=1 OR u=3 THEN PRINT inv$;ste$(z-13);
     nrm$:GOTO 560
<26> 540 IF u=2 THEN PRINT inv$;
<48> 550 PRINT MID$(bou$,8*f-7+(z-14)*48,6);nrm$
<70> 560 IF INKEY$>"" THEN GOSUB 2950:GOTO 590
<57> 570 NEXT z:FOR j=1 TO 80:NEXT j,i:FOR j=1 TO 
     1000:NEXT j,u:GOTO 510
<38> 580 '
<19> 590 IF FIND$("BOUNCE.SCO")="" THEN ng=1
<56> 600 GOSUB 2590:GOSUB 2620:sw=1024:sw1=sw
<61> 610 IF sw<1 THEN 660
<68> 620 sw1=sw1/2:GET 1,sw:a1=VAL(MID$(stu$,17,2)
     ):de=EOF(1):IF sw>999 AND a1>0 THEN GOSUB 301
     0:GOTO 3040
<67> 630 GET 1,sw+1:a2=VAL(MID$(stu$,17,2))
<14> 640 IF de<0 OR a1=0 THEN sw=sw-sw1:GOTO 610
<74> 650 IF de=0 AND a2>0 THEN sw=sw+sw1:GOTO 610
<70> 660 IF ng=1 THEN FOR i=1 TO 10:na$(i)="BOUNCE
     "+SPACE$(10):pu(i)=100*(11-i):le(i)=INT((10-i
     )/3)+1:bo(i)=le(i)-1:pt(i)=20*le(i):NEXT i:GO
     SUB 2610:GOTO 710
<96> 670 FOR i=1 TO 10:GET 2,i:na$(i)=name$:pu(i)=
     VAL(punkte$):le(i)=VAL(level$):bo(i)=VAL(bonu
     s$):pt(i)=VAL(dauer$):NEXT i
<39> 680 '
<33> 690 '***** Hauptprogramm ********************
     *****
<24> 700 '
< 8> 710 DIM zuf(sw),moe(sw,2):FOR i=1 TO sw:zuf(i
     )=i:NEXT i
<19> 720 k=1:k1=4:GOSUB 2710:PRINT lf1$:IF v(1)<>2
      THEN PRINT lf4$;lf3$
<81> 730 IF v(1)=1 THEN GOSUB 2990:st=0:ge=0:pun=0
     :lev=0:bon=0:pti=0:gbs=0:GOTO 770
<73> 740 IF v(1)=2 THEN GOSUB 2500:GOTO 720
<71> 750 IF v(1)=3 THEN swa=sw:GOSUB 2650:GOSUB 29
     90:GOTO 1740 ELSE 3040
<36> 760 '
<43> 770 FOR zu=sw TO 1 STEP -1
<15> 780 PRINT lf4$;inv$;und$;:s=0:FOR z=30 TO 0 S
     TEP -1:GOSUB 90:PRINT " ":NEXT z:PRINT nun$;n
     rm$
<51> 790 u=0:r=0:gc=FRE(""):lev=lev+1:lim=100:GOSU
     B 2640:GOSUB 2660:GOSUB 2670:GOSUB 2680:GOSUB
      2690
<58> 800 SWAP zuf(INT(zu*RND)+1),zuf(zu)
<64> 810 n=zuf(zu):GET 1,n:GOSUB 2850
<41> 820 FOR q=1 TO 2:FOR a=0 TO 7:r=r+1
<96> 830 IF (moe(n,q) AND 2^a)=0 THEN zm(r)=0:u=u+
     1:mt(u)=r ELSE zm(r)=1
<98> 840 NEXT a,q:m=mt(INT(u*RND)+1):zm(m)=1
<29> 850 IF m>8 THEN m=m-8:d=2 ELSE d=1
<40> 860 moe(n,d)=0:FOR a=0 TO 7
<34> 870 IF zm(a+d*8-7)=1 THEN moe(n,d)=moe(n,d)+2
     ^a
<28> 880 NEXT a
<83> 890 IF moe(n,1)+moe(n,2)=510 THEN moe(n,1)=0:
     moe(n,2)=0
<26> 900 '
<83> 910 FOR y=1 TO 8:by=VAL("&H"+MID$(stu$,2*y-1,
     2))
<98> 920 FOR a=0 TO 7:IF (by AND 2^a)=0 THEN 1040
<87> 930 x=a+1:ON m GOTO 940,950,960,970,980,990,1
     000,1010
<63> 940 x1=x:y1=y:GOTO 1020
<95> 950 x1=y:y1=9-x:GOTO 1020
<59> 960 x1=9-x:y1=9-y:GOTO 1020
<13> 970 x1=9-y:y1=x:GOTO 1020
< 9> 980 x1=x:y1=9-y:GOTO 1020
<68> 990 x1=y:y1=x:GOTO 1020
<96> 1000 x1=9-x:y1=y:GOTO 1020
<39> 1010 x1=9-y:y1=9-x:GOTO 1020
<35> 1020 fe(x1,y1)=1:st=st+1:IF a=bex(d)-1 AND y=
     bey(d) THEN ax=x1:ay=y1
<64> 1030 z=4*y1-4:s=8*x1-4:GOSUB 90:PRINT inv$;st
     e$(1):z=z+1:GOSUB 90:PRINT ste$(2):z=z+1:GOSU
     B 90:PRINT ste$(3);nrm$
<18> 1040 NEXT a,y
<65> 1050 GOSUB 3020:ptio=pti:ba=ba-1:IF ba<1 THEN
      ba=15
<66> 1060 f=INT(ba*RND)+1:SWAP b1(f),b1(ba):SWAP b
     2(f),b2(ba):POKE &HFBF7,0:POKE &HFBF8,0
< 5> 1070 '
<50> 1080 ta$=INKEY$:IF ta$>"" THEN 1220
<93> 1090 SWAP b1(ba),b2(ba):z=4*ay-3:s=8*ax-2:GOS
     UB 90:PRINT CHR$(b1(ba));CHR$(b2(ba))
<95> 1100 IF lim<30 THEN OUT 246,u1:SWAP u1,u2:hr=
     253+INT(lim/10):IF u1<u2 THEN u2=hr ELSE u1=h
     r
<13> 1110 IF RND>0.01 OR ge=1 THEN 1140
<85> 1120 xw=INT(8*RND)+1:yw=INT(8*RND)+1:IF fe(xw
     ,yw)=0 OR (xw-ax)^2+(yw-ay)^2<2 THEN 1160
<71> 1130 ge=1:bw=INT(6*RND):s=8*xw-4:FOR z=4*yw-4
      TO 4*yw-2:GOSUB 90:PRINT SPC(6):NEXT z:z=4*y
     w-1:FOR i=1 TO 3:z=z-1:GOSUB 90:PRINT inv$;MI
     D$(bou$,8*bw+1+(z-4*yw+4)*48,6);nrm$:NEXT i:z
     v=se
<40> 1140 ta$=INKEY$:IF ta$>"" THEN 1220
<52> 1150 IF ge=1 THEN IF se>zv+10 THEN ge=0:s=8*x
     w-4:FOR z=4*yw-4 TO 4*yw-2:GOSUB 90:PRINT SPC
     (6):NEXT z:FOR z=4*yw-2 TO 4*yw-4 STEP -1:GOS
     UB 90:PRINT inv$;ste$(z-4*yw+5);nrm$:NEXT z
<40> 1160 se=VAL(HEX$(PEEK(&HFBF7)))*60+VAL(HEX$(P
     EEK(&HFBF8))):IF se>100 THEN se=100
< 1> 1170 lim=100-se:pti=ptio+se:GOSUB 2680:GOSUB 
     2690
<52> 1180 ta$=INKEY$:IF ta$>"" THEN 1220
<88> 1190 PRINT esc$;"X. ";CHR$(31+se/3.27);" ";cl
     r$;nor$
<49> 1200 IF lim>0 THEN 1080 ELSE 1450
<90> 1210 '
<93> 1220 ta=ASC(ta$):ax1=ax:ay1=ay
< 1> 1230 IF ta=1 THEN ax=ax-1:GOTO 1350
<16> 1240 IF ta=6 THEN ax=ax+1:GOTO 1350
<32> 1250 IF ta=30 THEN ay=ay+1:GOTO 1350
<98> 1260 IF ta=31 THEN ay=ay-1:GOTO 1350
<54> 1270 IF ta=252 THEN ay=ay-2:GOTO 1350
<19> 1280 IF ta=253 THEN ay=ay+2:GOTO 1350
<41> 1290 IF ta=254 THEN ax=ax-2:GOTO 1350
<77> 1300 IF ta=255 THEN ax=ax+2:GOTO 1350
<72> 1310 IF ta=3 THEN ge=0:GOSUB 2890
<89> 1320 IF ta=21 THEN GOSUB 2970
<82> 1330 IF ta=23 THEN lem=n
<15> 1340 GOTO 1080
<79> 1350 OUT 248,tw:st=st-1:fe(ax1,ay1)=0:OUT 248
     ,12:PRINT esc$;"X";CHR$(4*ay1+28);CHR$(8*ax1+
     28);CHR$(34);CHR$(37);clr$;nor$
<92> 1360 IF ge=0 OR ax1<>xw OR ay1<>yw THEN 1390
<88> 1370 ge=0:bon=bon+1:GOSUB 2670:GOSUB 2960:pun
     =pun+(2*lim MOD 10):ep1=INT(2*lim/10):ep2=10:
     GOSUB 2870:IF (gbs AND 2^bw)=0 THEN gbs=gbs+2
     ^bw
<92> 1380 IF gbs>62 THEN gbs=0:FOR i=1 TO 3:PRINT 
     lf2$;he$:FOR j=1 TO 200:NEXT j:PRINT du$:FOR 
     bw=0 TO 5:GOSUB 2960:NEXT bw,i:ep1=25-INT(0.2
     5*pti/lev):ep2=100:GOSUB 2870:PRINT lf2$
<35> 1385 GOSUB 3020
<45> 1390 pun=pun+10:GOSUB 2640:IF st>0 THEN 1430
< 7> 1400 FOR i=1 TO 3:FOR j=1 TO 200:NEXT j:OUT 2
     48,tw:GOSUB 90:OUT 248,12:NEXT i:FOR j=1 TO 2
     00:NEXT j:pun=pun+(lim MOD 5):ep1=INT(lim/5):
     ep2=5:GOSUB 2870
< 6> 1410 SWAP w1,w2:FOR i=w1 TO w2 STEP SGN(1-w1)
     :OUT 246,i:FOR j=1 TO 1:NEXT j,i:OUT 246,0
<37> 1420 NEXT zu:GOTO 770
< 7> 1430 IF ax<1 OR ax>8 OR ay<1 OR ay>8 THEN 145
     0
<23> 1440 IF fe(ax,ay)>0 THEN 1080
<82> 1450 OUT 246,0:pti=ptio+se:GOSUB 2690
<64> 1460 FOR i=1 TO 10:FOR j=200 TO 220:OUT 248,t
     w:OUT 248,12:OUT 245,j:NEXT j,i:OUT 245,91
< 1> 1470 s=70:FOR z=26 TO 30:GOSUB 90:PRINT inv$;
     SPC(20):NEXT z:z=28:s=76:GOSUB 90:PRINT "GAME
      OVER";nrm$
<16> 1480 '
< 7> 1490 '***** Highscore ***********************
     *****
<93> 1500 '
<55> 1510 FOR h=10 TO 1 STEP -1
<44> 1520 IF pun>pu(h) THEN 1580
<49> 1530 IF pun<pu(h) THEN 1590
<62> 1540 IF lev>le(h) THEN 1580
<67> 1550 IF lev<le(h) THEN 1590
< 0> 1560 IF bon>bo(h) THEN 1580
<95> 1570 IF bon<bo(h) OR pti>pt(h) THEN 1590
<95> 1580 NEXT h
<87> 1590 IF h=10 THEN 720
<28> 1600 FOR j=10 TO h+2 STEP -1:na$(j)=na$(j-1):
     pu(j)=pu(j-1):le(j)=le(j-1):bo(j)=bo(j-1):pt(
     j)=pt(j-1):NEXT j
< 4> 1610 na$(h+1)=SPACE$(16):pu(h+1)=pun:le(h+1)=
     lev:bo(h+1)=bon:pt(h+1)=pti
<33> 1620 PRINT lf1$:GOSUB 2500:na$(h+1)="":GOSUB 
     3020:z=2*h+8:s=15:GOSUB 90:PRINT sic$;
<18> 1630 ta$=INPUT$(1):ta=ASC(ta$):IF ta>32 AND t
     a<127 THEN 1690
<29> 1640 IF ta=32 THEN IF s=15 THEN 1630 ELSE 169
     0
<57> 1650 IF ta=127 THEN IF s>15 THEN na$(h+1)=LEF
     T$(na$(h+1),LEN(na$(h+1))-1):s=s-1:GOSUB 90:P
     RINT " ";:GOSUB 90 ELSE GOSUB 3010
<47> 1660 IF ta=13 THEN IF na$(h+1)="" THEN GOSUB 
     3010:GOTO 1630 ELSE na$(h+1)=na$(h+1)+SPACE$(
     31-s):PRINT uns$:GOSUB 2610:GOTO 720
<11> 1670 IF ta=21 THEN GOSUB 2970
<40> 1680 GOTO 1630
<79> 1690 IF s<31 THEN GOSUB 90:PRINT ta$;:na$(h+1
     )=na$(h+1)+ta$:s=s+1:GOSUB 90 ELSE GOSUB 3010
<18> 1700 GOTO 1630
< 1> 1710 '
<10> 1720 '***** Editor **************************
     *****
< 7> 1730 '
<60> 1740 k=2:k1=3:GOSUB 2710
<76> 1750 IF v(2)=3 OR ta=8 THEN PRINT lf3$:IF sw<
     >swa THEN ERASE zuf,moe:GOTO 710 ELSE 720
<98> 1760 IF v(2)=1 THEN d=0:lev=sw+1:GOSUB 2660:G
     OSUB 3000:GOTO 2040
<10> 1770 num$="":z=7:s=85:GOSUB 90:PRINT sic$;
< 9> 1780 ta=ASC(INPUT$(1))
<44> 1790 IF ta=8 THEN PRINT uns$:GOSUB 2650:GOTO 
     1740
<34> 1800 IF ta=13 THEN 1860
<33> 1810 IF ta=127 THEN IF s=85 THEN GOSUB 3010 E
     LSE num$=LEFT$(num$,LEN(num$)-1):s=s-1:GOSUB 
     90:PRINT " ";:GOSUB 90
< 0> 1820 IF ta=21 THEN GOSUB 2970
<39> 1830 IF ta=23 THEN num$=STR$(lem):GOTO 1860
<12> 1840 IF ta>47 AND ta<58 THEN IF s=88 THEN GOS
     UB 3010 ELSE num$=num$+CHR$(ta):GOSUB 90:PRIN
     T CHR$(ta);:s=s+1:GOSUB 90
<13> 1850 GOTO 1780
<38> 1860 PRINT uns$;:lev=VAL(num$):IF lev<1 OR le
     v>sw THEN lev=lds
<10> 1870 GOSUB 2660:GET 1,lev:lds=lev:FOR y=1 TO 
     8:by=VAL("&H"+MID$(stu$,2*y-1,2)):FOR a=0 TO 
     7:b=2^a
<52> 1880 IF (by AND b)<>0 THEN fe(a+1,y)=1
<33> 1890 NEXT a,y:GOSUB 2850:GOSUB 3000:FOR b=1 T
     O 8:FOR a=1 TO 8
<67> 1900 IF fe(a,b)>0 THEN z=4*b-4:s=8*a-4:GOSUB 
     90:PRINT inv$;ste$(1):z=z+1:GOSUB 90:PRINT st
     e$(2):z=z+1:GOSUB 90:PRINT ste$(3);nrm$
<75> 1910 NEXT a,b:d=2:FOR i=1 TO 2:fe(bex(i),bey(
     i))=2:z=4*bey(i)-3:s=8*bex(i)-2:GOSUB 90:PRIN
     T CHR$(145);CHR$(148):NEXT i
< 8> 1920 '
<28> 1930 '***** Bearbeiten / L|schen ************
     *****
<14> 1940 '
<83> 1950 k=4:k1=3:GOSUB 2710
<76> 1960 IF v(4)=3 OR ta=8 THEN GOSUB 2650:PRINT 
     lf1$:GOSUB 2990:GOTO 1740
<69> 1970 IF v(4)=1 THEN x=bex(1):y=bey(1):z=4*y-3
     :s=8*x-3:GOSUB 90:PRINT inv$;CHR$(149):s=s+3:
     GOSUB 90:PRINT CHR$(149);nrm$:s=s-4:GOTO 2050
<87> 1980 k=5:k1=2:GOSUB 2710
<51> 1990 IF v(5)=2 OR ta=8 THEN 1950
<64> 2000 GET 1,sw:PUT 1,lev:LSET stu$="":PUT 1,sw
     :sw=sw-1:lem=1:lds=1:GOTO 2460
<87> 2010 '
<45> 2020 '***** Level erstellen *****************
     *****
<93> 2030 '
<56> 2040 x=1:y=1:z=1:s=4:GOSUB 90:PRINT cue$
<74> 2050 afe=fe(x,y)
<59> 2060 ta=ASC(INPUT$(1)):IF ta<>1 AND ta<>6 AND
      ta<>8 AND ta<>13 AND ta<>18 AND ta<>21 AND t
     a<>30 AND ta<>31 AND ta<251 THEN 2060
<62> 2070 IF ta=1 THEN x=x-1:IF x=0 THEN x=8
<78> 2080 IF ta=6 THEN x=x+1:IF x=9 THEN x=1
<32> 2090 IF ta=30 THEN y=y+1:IF y=9 THEN y=1
<67> 2100 IF ta=31 THEN y=y-1:IF y=0 THEN y=8
<70> 2110 IF ta=13 THEN IF d<>2 THEN GOSUB 3010:GO
     TO 2060
<18> 2120 IF ta=18 THEN 2320
<54> 2130 IF ta=8 THEN GOSUB 2650:PRINT lf1$:GOSUB
      2990:GOTO 1740
<47> 2140 IF ta=21 THEN GOSUB 2970:GOTO 2060
< 5> 2150 IF ta=251 THEN 2290
<10> 2160 IF ta=252 THEN y=y-2:IF y<1 THEN y=8
<77> 2170 IF ta=253 THEN y=y+2:IF y>8 THEN y=1
<30> 2180 IF ta=254 THEN x=x-2:IF x<1 THEN x=8
<97> 2190 IF ta=255 THEN x=x+2:IF x>8 THEN x=1
<28> 2200 GOSUB 90
<26> 2210 IF afe=0 THEN PRINT ". ";CHR$(146);CHR$(
     152);" "
<42> 2220 IF afe>0 THEN s=s+1:GOSUB 90:PRINT inv$;
     " ":s=s+3:GOSUB 90:PRINT " ";nrm$:s=s-4
<90> 2230 IF ta=13 THEN 2380
<38> 2240 z=4*y-3:s=8*x-4:GOSUB 90
<15> 2250 IF fe(x,y)=0 THEN PRINT cue$
<79> 2260 IF fe(x,y)>0 THEN s=s+1:GOSUB 90:PRINT i
     nv$;CHR$(149):s=s+3:GOSUB 90:PRINT CHR$(149);
     nrm$:s=s-4
<94> 2270 GOTO 2050
<13> 2280 '
<35> 2290 z=4*y-4:s=8*x-4:GOSUB 90:IF fe(x,y)>0 TH
     EN d=d-fe(x,y)+1:fe(x,y)=0:PRINT SPC(6):z=z+1
     :GOSUB 90:PRINT cue$:z=z+1:GOSUB 90:PRINT SPC
     (6):z=z-1:GOTO 2050
<37> 2300 fe(x,y)=1:PRINT inv$;ste$(1):z=z+1:GOSUB
      90:PRINT ve$;CHR$(149);". ";CHR$(149);ve$:z=
     z+1:GOSUB 90:PRINT ste$(3);nrm$:z=z-1:GOTO 20
     50
<93> 2310 '
<67> 2320 IF fe(x,y)=2 THEN fe(x,y)=1:d=d-1:s=s+2:
     GOSUB 90:PRINT inv$;". ";nrm$:s=s-2:GOTO 2060
<27> 2330 IF fe(x,y)=0 OR d=2 THEN GOSUB 3010:GOTO
      2060
<91> 2340 fe(x,y)=2:d=d+1:s=s+2:GOSUB 90:PRINT CHR
     $(145);CHR$(148):s=s-2:GOTO 2060
< 6> 2350 '
<16> 2360 '***** Level abspeichern ***************
     *****
<12> 2370 '
<73> 2380 k=3:k1=3:GOSUB 2710
<63> 2390 IF v(3)=3 OR ta=8 THEN GOSUB 2650:PRINT 
     lf1$:GOSUB 2990:GOTO 1740
<21> 2400 IF v(3)=2 THEN 2240
<87> 2410 nstu$="":zus$="":FOR y=1 TO 8:by=0:FOR a
     =0 TO 7:b=2^a:x=a+1
<87> 2420 IF fe(x,y)>0 THEN by=by+b
<37> 2430 IF fe(x,y)=2 THEN zus$=zus$+DEC$(10*x+y,
     "##")
<75> 2440 NEXT a:nstu$=nstu$+RIGHT$("0"+HEX$(by),2
     ):NEXT y
<78> 2450 LSET stu$=nstu$+zus$:IF v(2)=2 THEN PUT 
     1,lev ELSE sw=sw+1:PUT 1,sw:lds=sw
<69> 2460 CLOSE 1:GOSUB 2590:GOSUB 2650:PRINT lf1$
     :GOSUB 2990:GOTO 1740
<14> 2470 '
<16> 2480 '***** Unterroutinen *******************
     *****
<20> 2490 '
<43> 2500 z=2:s=9:GOSUB 90:PRINT STRING$(8,138);" 
     B O U N C E. -. H I G H S C O R E ";STRING$(8
     ,138):z=3:GOSUB 90:PRINT inv$;und$;SPC(51);nu
     n$;nrm$
<71> 2510 z=4:GOSUB 90:PRINT lo$;STRING$(22,138)CH
     R$(142)STRING$(7,138)CHR$(142)STRING$(5,138)C
     HR$(142)STRING$(5,138)CHR$(142)STRING$(6,138)
     ;ro$
<36> 2520 z=5:GOSUB 90:PRINT ve$;" Name des Spiele
     rs:.. ";ve$;" Score ";ve$;" Lev ";ve$;" Bon "
     ;ve$;" Sek. ";ve$
<50> 2530 z=6:GOSUB 90:PRINT CHR$(135)STRING$(22,1
     38)CHR$(143)STRING$(7,138)CHR$(143)STRING$(5,
     138)CHR$(143)STRING$(5,138)CHR$(143)STRING$(6
     ,138)CHR$(141)
<94> 2540 FOR z=7 TO 27 STEP 2:GOSUB 90:PRINT ve$S
     PC(22)ve$SPC(7)ve$SPC(5)ve$SPC(5)ve$SPC(6)ve$
     :NEXT z
<44> 2550 z=28:GOSUB 90:PRINT lu$STRING$(22,138)CH
     R$(139)STRING$(7,138)CHR$(139)STRING$(5,138)C
     HR$(139)STRING$(5,138)CHR$(139)STRING$(6,138)
     ru$
<22> 2560 FOR i=10 TO 1 STEP -1:z=2*i+6:GOSUB 90:P
     RINT ve$;DEC$(i,"###");". ";na$(i);" ";ve$;DE
     C$(pu(i),"######");" ";ve$;DEC$(le(i),"####")
     ;" ";ve$;DEC$(bo(i),"####");" ";ve$;DEC$(pt(i
     ),"#####");" ";ve$:NEXT i
<11> 2570 RETURN
<19> 2580 '
<94> 2590 OPEN "R",1,"BOUNCE.LEV",20:FIELD 1,20 AS
      stu$:RETURN
<96> 2600 '
< 2> 2610 FOR i=1 TO 10:LSET name$=na$(i):LSET pun
     kte$=DEC$(pu(i),"######"):LSET level$=DEC$(le
     (i),"####"):LSET bonus$=DEC$(bo(i),"####"):LS
     ET dauer$=DEC$(pt(i),"#####"):PUT 2,i:NEXT i:
     CLOSE 2
<53> 2620 OPEN "R",2,"BOUNCE.SCO",35:FIELD 2,16 AS
      name$,6 AS punkte$,4 AS level$,4 AS bonus$,5
      AS dauer$:RETURN
< 6> 2630 '
<31> 2640 z=6:s=82:GOSUB 90:PRINT USING"######";pu
     n:RETURN
<64> 2650 z=7:s=79:GOSUB 90:PRINT USING"(###)... "
     ;sw:RETURN
<39> 2660 z=7:s=84:GOSUB 90:PRINT USING"####";lev:
     RETURN
< 5> 2670 z=8:s=84:GOSUB 90:PRINT USING"####";bon:
     RETURN
< 7> 2680 z=9:s=85:GOSUB 90:PRINT USING"###";lim:R
     ETURN
<54> 2690 z=10:s=83:GOSUB 90:PRINT USING"#####";pt
     i:RETURN
<98> 2700 '
<64> 2710 z=19:s=70:GOSUB 90:PRINT lo$;ho$;ro$
< 0> 2720 z=20:GOSUB 90:PRINT ve$;inv$;men$(k,1);n
     rm$;ve$
<42> 2730 FOR z=21 TO 19+k1:GOSUB 90:PRINT ve$;men
     $(k,z-19);ve$:NEXT z
< 0> 2740 GOSUB 90:PRINT lu$;ho$;ru$
<35> 2750 v(k)=1:z=20:s=71:GOSUB 3020
<25> 2760 zu$=men$(k,v(k))
<40> 2770 ta=ASC(INPUT$(1)):IF ta<>8 AND ta<>13 AN
     D ta<>21 AND ta<>30 AND ta<>31 THEN 2770
<70> 2780 IF ta=30 THEN v(k)=v(k)+1:IF v(k)=k1+1 T
     HEN v(k)=1
<76> 2790 IF ta=31 THEN v(k)=v(k)-1:IF v(k)=0 THEN
      v(k)=k1
<29> 2800 IF ta=8 THEN IF k>1 AND k<6 THEN PRINT l
     f2$:RETURN ELSE GOSUB 3010:GOTO 2770
< 5> 2810 IF ta=13 THEN IF sw>998 AND k=2 AND v(2)
     =1 OR sw<1 AND (k=1 AND v(1)=1 OR k=2 AND v(2
     )=2) THEN GOSUB 3010:GOTO 2770 ELSE PRINT lf2
     $:RETURN
<55> 2820 IF ta=21 THEN GOSUB 2970:GOTO 2770
<49> 2830 GOSUB 90:PRINT zu$:z=v(k)+19:GOSUB 90:PR
     INT inv$;men$(k,v(k));nrm$:GOTO 2760
<13> 2840 '
<85> 2850 bex(1)=VAL(MID$(stu$,17,1)):bey(1)=VAL(M
     ID$(stu$,18,1)):bex(2)=VAL(MID$(stu$,19,1)):b
     ey(2)=VAL(MID$(stu$,20,1)):RETURN
<19> 2860 '
<10> 2870 z=6:s=71:GOSUB 90:PRINT inv$;" Score: ";
     nrm$:FOR i=1 TO ep1:OUT 248,tw:pun=pun+ep2:OU
     T 248,12:GOSUB 2640:NEXT i:s=71:GOSUB 90:PRIN
     T " Score: ":RETURN
<25> 2880 '
<90> 2890 me1=PEEK(&HFBF7):me2=PEEK(&HFBF8):se=VAL
     (HEX$(me1))*60+VAL(HEX$(me2)):IF se>100 THEN 
     se=100
<63> 2900 lim=100-se:GOSUB 2680:pti=ptio+se:GOSUB 
     2690
<17> 2910 PRINT lf1$:tz=INT(13*RND)-6:FOR i=1 TO 5
     :FOR j=1 TO 5:z=tz*(i-3)+j+12:s=i*11-1:GOSUB 
     90:PRINT pa$(jn(i*5+j-5)):NEXT j,i:GOSUB 3020
     :ta$=INPUT$(1):OUT 245,INT(91*RND):PRINT lf1$
<82> 2920 FOR b=1 TO 8:FOR a=1 TO 8:OUT 246,72-b*8
     -a:IF fe(a,b)>0 THEN OUT 248,tw:s=8*a-4:OUT 2
     48,12:FOR i=1 TO 3:z=4*b-5+i:GOSUB 90:PRINT i
     nv$;ste$(i);nrm$:NEXT i
<33> 2930 NEXT a,b:POKE &HFBF7,me1:POKE &HFBF8,me2
     :OUT 245,91:GOSUB 3020:RETURN
<15> 2940 '
<92> 2950 s=12:FOR z=14 TO 16:GOSUB 90:PRINT MID$(
     bou$,(z-14)*48+1,48):NEXT z:RETURN
<98> 2960 ff=13+3*INT(bw/3):s=(bw MOD 3)*7+70:FOR 
     z=ff TO ff+2:GOSUB 90:PRINT MID$(bou$,8*bw+1+
     (z-ff)*48,6);:NEXT z:RETURN
< 3> 2970 z1=z:s1=s:SWAP tw,tw1:SWAP so$,so1$:z=11
     :s=85:GOSUB 90:PRINT so$:z=z1:s=s1:GOSUB 90:R
     ETURN
<27> 2980 '
<54> 2990 FOR a=1 TO 8:FOR b=1 TO 8:fe(a,b)=0:NEXT
      b,a:RETURN
<18> 3000 s=3:FOR z=1 TO 29 STEP 4:GOSUB 90:PRINT 
     eli$:NEXT z:RETURN
<90> 3010 OUT 248,tw:FOR i=1 TO 500:NEXT i:OUT 248
     ,12:RETURN
<74> 3020 IF INKEY$<>"" THEN 3020 ELSE RETURN
<94> 3030 '
<36> 3040 CLOSE:k=6:k1=4:GOSUB 2710:PRINT clr$;sic
     $;
<74> 3050 IF v(6)=4 THEN OUT 248,1
<17> 3060 IF v(6)=3 THEN PRINT esc$;"x";:SYSTEM
<92> 3070 IF v(6)=2 THEN SYSTEM
<92> 3080 END

[BOUNCE.BAS]

LISTING >LEVEL<, REMARK = >'<.
 
<36> 100 '****************************************
     ******
<26> 110 '*......... Dieses Programm enth{lt......
     .... *
< 3> 120 '*... 100 getestete Level f}r das Spiel..
     .... *
<45> 130 '*. BOUNCE V 1.4. (C) 12.05.1991 by H. Ge
     yer. *
<57> 140 '*. Jeweils 5 DATA-Werte ergeben einen Le
     vel. *
<46> 150 '****************************************
     ******
< 6> 160 CLEAR ,,,1,20
< 5> 170 OPEN "R",1,"BOUNCE.LEV",20:FIELD 1,20 AS 
     stu$
<20> 180 FOR i=1 TO 100:a$="":FOR j=1 TO 5
<66> 190 READ b$:a$=a$+b$:by=by+ABS(VAL("&H"+b$))
< 8> 200 NEXT j:LSET stu$=a$:PUT 1,i:NEXT i
<81> 210 IF by<>7013109! THEN PRINT "Datafehler!"
<28> 220 END
<25> 230 '
<58> 240 DATA 1A54,1A47,0A45,0A50,2127,50D0,CD56,D
     B15
<28> 250 DATA 1000,2557,4000,D457,D114,0F14,3338,4
     2F7
<11> 260 DATA 4A00,42FE,461A,2146,F002,DF12,4362,0
     BF8
<67> 270 DATA 7143,40EE,444C,1F46,A4EC,7367,4D55,4
     805
<66> 280 DATA 2960,A7FA,7334,2227,722A,4A5F,4243,6
     136
<84> 290 DATA 1410,063C,0250,1600,3464,2075,0B09,3
     E2B
<51> 300 DATA 0200,6123,A61C,A7F4,247A,0527,8364,1
     E60
<54> 310 DATA 1CAA,E882,A0AF,2153,80BF,9890,16B8,5
     2D6
< 9> 320 DATA 8157,6171,2766,241A,7050,7112,145F,5
     4C5
< 8> 330 DATA 4FA0,70A0,3477,005A,4A74,742E,5400,7
     336
<78> 340 DATA 08E8,3F40,E95B,086A,2385,0050,4B1D,0
     4C4
<91> 350 DATA 2EF4,2788,BEA8,5DAA,49BA,C995,2143,0
     074
<13> 360 DATA 0E24,2E34,2420,7225,FF89,AD89,8BA5,8
     1FF
<36> 370 DATA 4418,0079,A1C5,A475,042E,1256,283E,0
     8F2
<75> 380 DATA 0812,1E0A,3237,0716,F85A,0602,5EE8,1
     174
<36> 390 DATA 0405,041F,5451,E84D,2447,F507,320E,D
     42C
<98> 400 DATA 80F8,5358,0055,BB51,A20A,7A42,8378,1
     2FB
<40> 410 DATA 12D3,8A18,CF00,1277,A8DD,091C,0911,7
     539
< 3> 420 DATA 7217,0704,1216,3B4A,EB74,1517,AB55,A
     857
<30> 430 DATA 6AF2,4000,2126,84AF,8174,2527,782F,3
     181
<24> 440 DATA C8AA,C80F,C178,E95B,8134,C017,CC99,D
     441
<15> 450 DATA EF41,4427,0055,2A21,FB21,1331,7257,0
     000
<56> 460 DATA B02A,D8D6,E800,2467,0040,EC5A,770A,7
     000
<51> 470 DATA 3346,2A74,6614,2EB4,2E00,5427,0003,0
     057
< 8> 480 DATA 6816,0A05,3418,0503,050A,2CAA,3400,1
     157
<34> 490 DATA 0034,18E4,1C5E,0800,4676,0000,A276,B
     E68
<85> 500 DATA 0028,5425,554E,F52B,11F1,A140,2264,0
     028
<38> 510 DATA 660A,0C76,182C,2326,7D36,D52A,B902,A
     D06
<72> 520 DATA 6245,302A,142A,060A,7C2A,4228,00F5,C
     B74
< 9> 530 DATA 0B2D,0600,3466,28FF,8061,8348,6A68,2
     264
<37> 540 DATA 0A53,1469,7CC9,34AD,3367,E057,9862,A
     856
<29> 550 DATA C600,3256,5AA7,7194,1BC6,58EC,7334,D
     430
<32> 560 DATA 9620,D635,5263,6427,0517,6518,F4A8,5
     65A
<23> 570 DATA 3375,00DA,5486,6B8D,E00B,3348,006B,1
     659
<20> 580 DATA 420B,5514,3325,63AA,D718,C668,0A00,1
     366
<83> 590 DATA 281D,6358,16CA,A800,2335,0002,5ABA,4
     6B0
<66> 600 DATA 572A,4437,5628,572A,1D62,5D03,3347,0
     050
<36> 610 DATA 10EA,107F,90AC,2476,FF40,A073,2914,0
     D05
<37> 620 DATA 5618,1435,1CE1,1AC9,32A7,6243,4EE2,4
     43A
<76> 630 DATA AA12,A23C,3373,0755,07F8,194B,0557,2
     176
<24> 640 DATA 6058,35CD,A847,5214,1345,520F,5A68,4
     80A
<77> 650 DATA 2A28,5327,A02A,96D0,AF09,340B,7435,4
     3AB
<33> 660 DATA E514,00DA,2AA2,7627,9DE3,8EA2,62BE,6
     A52
<57> 670 DATA 3383,0E0A,635F,2922,5678,1345,0107,1
     B6D
<94> 680 DATA 334A,296D,1446,D50A,8C63,AE51,96AB,1
     145
<31> 690 DATA 6AC2,B51A,AFD4,37ED,1345,15EB,9825,C
     632
<15> 700 DATA D7AA,1128,1895,C9CE,6BC4,2CA4,2465,5
     7A1
<81> 710 DATA 288F,D801,2DFD,2467,ED49,0A09,DA89,6
     AC3
<64> 720 DATA 2546,E796,A590,9BEC,8780,3136,3EC4,F
     2A9
<95> 730 DATA 137B,6000,4477,605A,36C6,30AF,D085,3
     377
<70> 740 DATA 021B,D7A8,32D6,0A68,3336,00F6,A34A,5
     BA0
<79> 750 DATA DEA8,2255,3A2C,16A8,D65A,6C57,4176,0
     01A
<17> 760 DATA 07B4,2A8B,55D8,1358,46FA,4C12,0897,A
     8B5
<85> 770 DATA 7338,AA1A,90AD,3B86,D080,1586,00A5,D
     639
<35> 780 DATA 271A,3400,4426,2833,DB25,DD71,0414,6
     445
<43> 790 DATA 160C,3A56,6C0E,602C,3568,00A0,B6DA,A
     C66
<18> 800 DATA A8AC,4485,0C28,A6D4,2BF5,0CA8,3448,0
     8ED
<25> 810 DATA 8B48,D4AD,1530,3216,A095,A57A,946E,B
     800
<70> 820 DATA 1267,D428,BC94,16CA,186A,3428,00D5,2
     BEA
< 0> 830 DATA BD4A,7E18,3558,0033,2DDB,35D8,6B0D,1
     386
<93> 840 DATA 0056,2C6A,5218,4AE8,3377,002F,A21D,C
     61B
<87> 850 DATA 5400,2377,1404,1AEC,5A94,56C0,3227,D
     095
<74> 860 DATA 73AC,4A0C,521A,4528

[LEVEL.BAS]

Dies sind folgende Tasten:

Tastennummer	Taste
7	[]
14	↑
79	↓
15	←
6	→