PAL20X8                                            PAL DESIGN SPECIFICATION
P7043                                                  NADIA SACHS 08/14/81
32-BIT CRC (CYCLICAL REDUNDANCY CHECKING) ERROR DETECTION CHIP 3
MMI SUNNYVALE,CALIFORNIA
CLK INIT C IN /Q15 /Q31 NC NC NC NC NC GND
/OC NC /Q23 /Q22 /Q21 /Q20 /Q19 /Q18 /Q17 /Q16 /CHK3 VCC


IF(VCC) CHK3  = /Q16*/Q17* Q18*/Q19*/Q20*/Q21*/Q22*/Q23   ;CHECK BIT 3

Q16  :=   Q15                                             ;SHIFT
      +   INIT                                            ;INITIALIZE
     :+: /INIT* C* IN*/Q31                                ;MODULO-2
      +  /INIT* C*/IN* Q31                                ;ADDITION

Q17  :=   Q16                                             ;SHIFT
      +   INIT                                            ;INITIALIZE

Q18  :=   Q17                                             ;SHIFT
      +   INIT                                            ;INITIALIZE

Q19  :=   Q18                                             ;SHIFT
      +   INIT                                            ;INITIALIZE

Q20  :=   Q19                                             ;SHIFT
      +   INIT                                            ;INITIALIZE

Q21  :=   Q20                                             ;SHIFT
      +   INIT                                            ;INITIALIZE

Q22  :=   Q21                                             ;SHIFT
      +   INIT                                            ;INITIALIZE
     :+: /INIT* C* IN*/Q31                                ;MODULO-2
      +  /INIT* C*/IN* Q31                                ;ADDITION

Q23  :=   Q22                                             ;SHIFT
      +   INIT                                            ;INITIALIZE
     :+: /INIT* C* IN*/Q31                                ;MODULO-2
      +  /INIT* C*/IN* Q31                                ;ADDITION


FUNCTION TABLE

CLK /OC INIT C IN Q15 Q31 Q23 Q22 Q21 Q20 Q19 Q18 Q17 Q16 CHK3

;                            Q   Q   QQQQQQQQ
;                            1   3   22221111
;CLK   /OC   INIT   C   IN   5   1   32109876   CHK3
-----------------------------------------------------
  C     L     H     X   X    X   X   HHHHHHHH    X
  C     L     L     H   L    H   H   LLHHHHHL    L
  C     L     L     H   L    H   H   HLHHHHLL    L
  C     L     L     H   L    H   H   HLHHHLLL    X
  C     L     L     H   L    H   H   HLHHLLLL    X
  C     L     L     H   L    L   H   HLHLLLLH    X
  C     L     L     H   L    H   H   HLLLLLHL    X
  C     L     L     H   L    L   L   LLLLLHLL    X
  C     L     L     H   L    L   L   LLLLHLLL    X
  C     L     L     H   L    H   L   LLLHLLLH    X
  C     L     L     H   L    L   H   HHHLLLHH    X
  C     L     L     H   L    H   L   HHLLLHHH    X
  C     L     L     H   L    H   L   HLLLHHHH    X
  C     L     L     H   L    H   H   HHLHHHHL    X
  C     L     L     H   L    L   H   LHHHHHLH    X
  C     L     L     H   L    L   H   LLHHHLHH    X
  C     L     L     H   L    L   H   HLHHLHHH    X
  C     L     L     H   L    L   L   LHHLHHHL    X
  C     L     L     H   L    H   L   HHLHHHLH    X
  C     L     L     H   L    H   L   HLHHHLHH    X
  C     L     L     H   L    L   L   LHHHLHHL    X
  C     L     L     H   L    L   L   HHHLHHLL    X
  C     L     L     H   L    H   L   HHLHHLLH    X
  C     L     L     H   L    L   L   HLHHLLHL    X
  C     L     L     H   L    L   L   LHHLLHLL    X
  C     L     L     H   L    L   H   LLLLHLLH    X
  C     L     L     H   L    H   L   LLLHLLHH    X
  C     L     L     H   L    H   H   HHHLLHHL    X
  C     L     L     H   L    H   H   LLLLHHLL    X
  C     L     L     H   L    L   L   LLLHHLLL    X
  C     L     L     H   L    L   H   HHHHLLLH    X
  C     L     L     H   L    L   L   HHHLLLHL    X
  C     L     L     H   L    H   H   LLLLLHLL    H
-----------------------------------------------------


DESCRIPTION

THIRD 8-BIT SHIFT REGISTER AND CHECK.