PAL20X4                                             PAL DESIGN SPECIFICATION
P7027                                                  BIRKNER/COLI 07/29/81
4-BIT FLASH GRAY A/D CONVERTER
MMI SUNNYVALE, CALIFORNIA
CLK A6 A7 A8 A9 A10 A11 A12 A13 A14 A15 GND
/OC A1 A2 A3 /G3 /G2 /G1 /G0 A4 A5 NC VCC


G0 :=  /A3 * A1    ;CONVERT ANALOG TO G0 (LSB)
    +  /A7 * A5
   :+: /A11* A9
    +  /A15* A13

G1 :=  /A6 * A2    ;CONVERT ANALOG TO G1
    +  /A14* A10

G2 :=  /A12* A4    ;CONVERT ANALOG TO G2

G3 :=   A8         ;CONVERT ANALOG TO G3 (MSB)


FUNCTION TABLE

/OC CLK A15 A14 A13 A12 A11 A10 A9 A8 A7 A6 A5 A4 A3 A2 A1 G3 G2 G1 G0

;          ANALOG  INPUTS     GRAY
;CONTROL   111111            OUTPUTS    COMMENTS
;/OC CLK   543210987654321    3210      FRACTION OF Vmax
---------------------------------------------------------
  L   C    LLLLLLLLLLLLLLL    LLLL      V=0
  L   C    LLLLLLLLLLLLLLH    LLLH      V=1/16
  L   C    LLLLLLLLLLLLLHH    LLHH      V=1/8
  L   C    LLLLLLLLLLLLHHH    LLHL      V=3/16
  L   C    LLLLLLLLLLLHHHH    LHHL      V=1/4
  L   C    LLLLLLLLLLHHHHH    LHHH      V=5/16
  L   C    LLLLLLLLLHHHHHH    LHLH      V=3/8
  L   C    LLLLLLLLHHHHHHH    LHLL      V=7/16
  L   C    LLLLLLLHHHHHHHH    HHLL      V=1/2
  L   C    LLLLLLHHHHHHHHH    HHLH      V=9/16
  L   C    LLLLLHHHHHHHHHH    HHHH      V=5/8
  L   C    LLLLHHHHHHHHHHH    HHHL      V=11/16
  L   C    LLLHHHHHHHHHHHH    HLHL      V=3/4
  L   C    LLHHHHHHHHHHHHH    HLHH      V=13/16
  L   C    LHHHHHHHHHHHHHH    HLLH      V=7/8
  L   C    HHHHHHHHHHHHHHH    HLLL      V=15/16
  H   X    XXXXXXXXXXXXXXX    ZZZZ      TEST HI-Z
---------------------------------------------------------


DESCRIPTION

THE 4-BIT FLASH ANALOG-TO-DIGITAL CONVERTER CONVERTS AN ANALOG SIGNAL
INTO A 4-BIT GRAY CODE.  GRAY CODE IS CHOSEN TO ELIMINATE GLITCHES AT
BINARY ROLL OVER POINTS.

THE MAXIUM SAMPLE RATE IS EQUAL TO 1/tpd OF THE PAL20X4.  NOTE THAT NO
FEEDBACK PROPAGATION DELAY IS INTRODUCED.