PAL16X4                                        PAL DESIGN SPECIFICATION
P7045                                               B. BRAFMAN 02/16/81
CHECK BIT GENERATOR
MMI FIELD APPLICATIONS ENGINEER YORBA LINDA, CALIFORNIA
CHKCLK B7 B6 NC NC NC NC B5 B4 GND
/OC B3 B2 /C0 /C1 /C2 /C3 B1 B0 VCC


C3 :=   B7*/B6               ;B7 :+: B6
    +  /B7* B6               ;   :+:
   :+:  B5*/B4               ;B5 :+: B4
    +  /B5* B4

C2 :=   B7*/B3               ;B7 :+: B3
    +  /B7* B3               ;   :+:
   :+:  B2*/B1               ;B2 :+: B1
    +  /B2* B1

C1 :=   B6* B5* B3           ;B6 :+: B5 :+: B3
    +  /B6*/B5* B3
    +  /B6* B5*/B3           ;   :+:
    +   B6*/B5*/B3
   :+:  B2*/B0               ;B2 :+: B0
    +  /B2* B0

C0 :=   B6* B4* B3           ;B6 :+: B4 :+: B3
    +  /B6*/B4* B3
    +  /B6* B4*/B3           ;   :+:
    +   B6*/B4*/B3
   :+:  B1*/B0               ;B1 :+: B0
    +  /B1* B0


FUNCTION TABLE

CHKCLK /OC B7 B6 B5 B4 B3 B2 B1 B0 C3 C2 C1 C0

;CONTROL   8 BIT IN   CORR
;CHK  /    BBBBBBBB   CCCC
;CLK  OC   76543210   3210    COMMENTS
-------------------------------------------------
  C   L    HHHHHHHH   LLHH    ALL ONES DATA
  C   L    LHHHHHHH   HHHH    SHIFT A ZERO ACROSS
  C   L    HLHHHHHH   HLLL
  C   L    HHLHHHHH   HLLH
  C   L    HHHLHHHH   HLHL
  C   L    HHHHLHHH   LHLL
  C   L    HHHHHLHH   LHLH
  C   L    HHHHHHLH   LHHL
  C   L    HHHHHHHL   LLLL
  C   L    LLLLLLLL   LLLL    ALL ZEROS DATA
  C   L    HLLLLLLL   HHLL    SHIFT A ONE ACROSS
  C   L    LHLLLLLL   HLHH
  C   L    LLHLLLLL   HLHL
  C   L    LLLHLLLL   HLLH
  C   L    LLLLHLLL   LHHH
  C   L    LLLLLHLL   LHHL
  C   L    LLLLLLHL   LHLH
  C   L    LLLLLLLH   LLHH
-------------------------------------------------


DESCRIPTION

THIS PAL GENERATES THE 4 CHECK BITS IN A 12 BIT HAMMING CODE WORD TO
PROVIDE ERROR DETECTION AND CORRECTION ON AN 8 BIT DATA WORD.