PAL16R4                                          PAL DESIGN SPECIFICATION
P7028                                               BIRKNER/COLI 07/30/81
4-BIT GRAY D/A CONVERTER
MMI SUNNYVALE, CALIFORNIA
 CLK NC NC  G0  G1  G2  G3 NC /OC2 GND
/OC1 A3 A2 /B3 /B2 /B1 /B0 A1  A0  VCC


B0 :=  /G0* G1* G2* G3 ;CONVERT GRAY TO B0 (LSB)
    +   G0*/G1* G2* G3
    +   G0* G1*/G2* G3
    +   G0* G1* G2*/G3
    +   G0*/G1*/G2*/G3
    +  /G0* G1*/G2*/G3
    +  /G0*/G1* G2*/G3
    +  /G0*/G1*/G2* G3

B1 :=  /G1*/G2* G3     ;CONVERT GRAY TO B1
    +  /G1* G2*/G3
    +   G1*/G2*/G3
    +   G1* G2* G3

B2 :=  /G2* G3         ;CONVERT GRAY TO B2
    +   G2*/G3

B3 :=   G3             ;CONVERT GRAY TO B3 (MSB)

IF(B0*OC2) /A0 =  B0   ;CONVERT B0 TO ANALOG

IF(B1*OC2) /A1 =  B1   ;CONVERT B1 TO ANALOG

IF(B2*OC2) /A2 =  B2   ;CONVERT B2 TO ANALOG

IF(B3*OC2) /A3 =  B3   ;CONVERT B3 TO ANALOG


FUNCTION TABLE

/OC1 /OC2 CLK G3 G2 G1 G0 B3 B2 B1 B0 A3 A2 A1 A0

;---CONTROL---   GRAY   BCD    ANALOG    COMMENTS
;/OC1 /OC2 CLK   3210   3210    3210     FRACTION OF Vmax
----------------------------------------------------------
   L    L   C    LLLL   LLLL    ZZZZ     V=0
   L    L   C    LLLH   LLLH    ZZZL     V=1/16
   L    L   C    LLHH   LLHL    ZZLZ     V=1/8
   L    L   C    LLHL   LLHH    ZZLL     V=3/16
   L    L   C    LHHL   LHLL    ZLZZ     V=1/4
   L    L   C    LHHH   LHLH    ZLZL     V=5/16
   L    L   C    LHLH   LHHL    ZLLZ     V=3/8
   L    L   C    LHLL   LHHH    ZLLL     V=7/16
   L    L   C    HHLL   HLLL    LZZZ     V=1/2
   L    L   C    HHLH   HLLH    LZZL     V=9/16
   L    L   C    HHHH   HLHL    LZLZ     V=5/8
   L    L   C    HHHL   HLHH    LZLL     V=11/16
   L    L   C    HLHL   HHLL    LLZZ     V=3/4
   L    L   C    HLHH   HHLH    LLZL     V=13/16
   L    L   C    HLLH   HHHL    LLLZ     V=7/8
   L    L   C    HLLL   HHHH    LLLL     V=15/16
   H    X   X    XXXX   ZZZZ    XXXX     TEST HI-Z (REG)
   X    H   X    XXXX   XXXX    ZZZZ     TEST HI-Z (OC)
----------------------------------------------------------


DESCRIPTION

THE 4-BIT FLASH DIGITAL-TO-ANALOG CONVERTER CONVERTS A 4-BIT GRAY CODE (G)
INTO A 4-BIT BINARY CODE (B), WHICH IS THEN CONVERTED INTO ANALOG OUTPUTS (A).

ANALOG OUTPUTS (A) ARE EITHER LOW OR HI-Z WHICH ALLOWS THE CONDITIONAL
THREE-STATE OUTPUTS TO PERFORM THE OPEN COLLECTOR FUNCTION THAT IS NEEDED TO
DRIVE THE RESISTOR NETWORK.