PAL16R4                                          PAL DESIGN SPECIFICATION
P7006                                            VINCENT LECLERC 03/03/81
DEGLITCHER
MMI FRANCE
CLK Z PRS CLR NC NC NC NC NC GND /OC ES BS NC Y X ZS ZD A VCC


/ZS := /PRS*/Z
     +  CLR                       ;CLEAR

/X  := /PRS*/X*/Y
     + /PRS*/X   */ZS
     + /PRS*   /Y*/ZS
     +  CLR                       ;CLEAR

/Y  := /PRS*/ZS
     +  CLR                       ;CLEAR

IF(VCC) /BS =  X + /Y + /ZS       ;BEGINNING OF SIGNAL

IF(VCC) /ES = /X +  Y +  ZS       ;END OF SIGNAL

IF(VCC) /A  = /PRS*ZD*/BS*/ES   
            + /PRS*ZD        */A
            + /PRS   * BS    */A
            + /PRS       * ES*/A
            +  CLR                ;CLEAR

IF(VCC) /ZD = /PRS*/A* BS
            + /PRS*/A* ES
            + /PRS*/A*/ZD
            + /PRS*/BS*/ES*/ZD    ;Z DETECTED
            + CLR                 ;CLEAR


FUNCTION TABLE

CLK /OC Z PRS CLR X Y ZS BS ES ZD A   ;COMMENTS
---------------------------------------------------------
 C   L  X  L   H  L L  L  L  L  L L    CLEAR
 C   L  L  L   L  L L  L  L  L  L H    INITIAL STATE S00
 C   L  H  L   L  L L  H  L  L  L H    INPUT Z
 C   L  L  L   L  L H  L  L  L  L H    STATE S00 TO S01
 C   L  H  L   L  L L  H  L  L  L H    STATE S01 TO S00
 C   L  H  L   L  L H  H  H  L  H H    STATE S00 TO S01
 C   L  L  L   L  H H  L  L  L  H L    STATE S01 TO S11
 C   L  L  L   L  H L  L  L  H  H H    STATE S11 TO S10
 C   L  L  L   L  L L  L  L  L  L H    STATE S10 TO S00
 C   L  X  H   L  H H  H  L  L  H H    PRESET TEST
 X   H  X  X   X  Z Z  Z  X  X  X X    ENABLE TEST
---------------------------------------------------------


DESCRIPTION

THE SYSTEM DETECTS THE BEGINNING AND THE END OF A SIGNAL WHICH IS
DISTURBED BY GLITCHES.