PAL16R8                                        PAL DESIGN SPECIFICATION
P7001                                             VINCENT COLI 07/19/81
BASIC CLOCKED FLIP-FLOPS
MMI SUNNYVALE, CALIFORNIA
CLK J K T PR CLR D S R GND
/OC /SRC /SRT /DC /DT /TC /TT /JKC /JKT VCC


JKT :=  J*/JKT*/CLR       ;J-K FLIP-FLOP (TRUE)
     + /K* JKT*/CLR       ;(JKT = Q)
     +  PR                ;PRESET Q

JKC := /J* K  */PR        ;J-K FLIP-FLOP (COMPLEMENT)
     + /J*/JKT*/PR        ;(JKC = /Q)
     +  K* JKT*/PR        ;
     +  CLR               ;CLEAR /Q

TT  :=  T*/TT*/CLR        ;T FLIP-FLOP (TRUE)
     + /T* TT*/CLR        ;(TT = Q)
     +  PR                ;PRESET Q

TC  := /T*/TT*/PR         ;T FLIP-FLOP (COMPLEMENT)
     +  T* TT*/PR         ;(TC = /Q)
     +  CLR               ;CLEAR /Q

DT  :=  D*/CLR            ;D FLIP-FLOP (TRUE) (DT = Q)
     +  PR                ;PRESET Q

DC  := /D*/PR             ;D FLIP-FLOP (COMPLEMENT) (DC = /Q)
     +  CLR               ;CLEAR /Q

SRT :=  S*     /CLR       ;SET-RESET FLIP-FLOP (TRUE)
     + /R* SRT*/CLR       ;(SRT = Q)
     +  PR                ;PRESET Q

SRC := /S* R  */PR        ;SET-RESET FLIP-FLOP (COMPLEMENT)
     + /S*/SRT*/PR        ;(SRC = /Q)
     +  CLR               ;CLEAR /Q


FUNCTION TABLE

CLK /OC PR CLR J K JKT JKC T TT TC D DT DC S R SRT SRC

;   CONTROL    J-K FLIP-FLOP  T FLIP-FLOP  D FLIP-FLOP  S-R FLIP-FLOP
; C  /           IN    OUT     IN   OUT     IN   OUT      IN    OUT
;LK OC PR CLR   J  K  Q  /Q    T   Q  /Q    D   Q  /Q    S  R  Q  /Q    COMMENT
-------------------------------------------------------------------------------
  X  H  X  X    X  X  Z   Z    X   Z   Z    X   Z   Z    X  X  Z   Z    HI-Z
;
;   TEST J-K FLIP-FLOP
;
  C  L  L  H    X  X  L   H    X   X   X    X   X   X    X  X  X   X    CLEAR
  C  L  L  L    L  L  L   H    X   X   X    X   X   X    X  X  X   X
  C  L  L  L    L  H  L   H    X   X   X    X   X   X    X  X  X   X
  C  L  L  L    H  H  H   L    X   X   X    X   X   X    X  X  X   X    TOGGLE
  C  L  L  L    H  L  H   L    X   X   X    X   X   X    X  X  X   X
  C  L  L  L    L  L  H   L    X   X   X    X   X   X    X  X  X   X
  C  L  L  L    L  H  L   H    X   X   X    X   X   X    X  X  X   X
  C  L  H  L    X  X  H   L    X   X   X    X   X   X    X  X  X   X    PRESET
  C  L  L  L    H  H  L   H    X   X   X    X   X   X    X  X  X   X    TOGGLE
  C  L  L  L    H  L  H   L    X   X   X    X   X   X    X  X  X   X
;
;   TEST T FLIP-FLOP
;
  C  L  L  H    X  X  X   X    X   L   H    X   X   X    X  X  X   X    CLEAR
  C  L  L  L    X  X  X   X    L   L   H    X   X   X    X  X  X   X
  C  L  L  L    X  X  X   X    H   H   L    X   X   X    X  X  X   X    TOGGLE
  C  L  L  L    X  X  X   X    H   L   H    X   X   X    X  X  X   X    TOGGLE
  C  L  H  L    X  X  X   X    X   H   L    X   X   X    X  X  X   X    PRESET
;
;   TEST D FLIP-FLOP
;
  C  L  L  H    X  X  X   X    X   X   X    X   L   H    X  X  X   X    CLEAR
  C  L  L  L    X  X  X   X    X   X   X    L   L   H    X  X  X   X
  C  L  L  L    X  X  X   X    X   X   X    H   H   L    X  X  X   X
  C  L  L  L    X  X  X   X    X   X   X    L   L   H    X  X  X   X
  C  L  H  L    X  X  X   X    X   X   X    X   H   L    X  X  X   X    PRESET
;
;   TEST S-R FLIP-FLOP
;
  C  L  L  H    X  X  X   X    X   X   X    X   X   X    X  X  L   H    CLEAR
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    L  L  L   H
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    H  L  H   L    SET
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    L  H  L   H    RESET
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    L  H  L   H    HOLD
  C  L  H  L    X  X  X   X    X   X   X    X   X   X    X  X  H   L    PRESET
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    L  L  H   L
  C  L  L  L    X  X  X   X    X   X   X    X   X   X    H  L  H   L
-------------------------------------------------------------------------------


DESCRIPTION

THIS EXAMPLE ILLUSTRATES THE USE OF FUSIBLE LOGIC TO IMPLEMENT THE BASIC
FLIP-FLOPS:  J-K FLIP-FLOP, T FLIP-FLOP, D FLIP-FLOP, AND S-R FLIP-FLOP.

NEXT STATE TABLE FOR THE BASIC FLIP-FLOPS:

      -------------------------------------------------------------
      !           !       !       Q = L       !       Q = H       !
      !  TYPE OF  !       !-------------------!-------------------!
      ! FLIP-FLOP ! INPUT ! Q+ =  L ! Q+ =  H ! Q+ =  L ! Q+ =  H !
      !-----------!-------!---------!---------!---------!---------!
      !    J-K    !   J   !    L    !    H    !    X    !    X    !
      !           !   K   !    X    !    X    !    H    !    L    !
      !-----------!-------!---------!---------!---------!---------!
      !     T     !   T   !    L    !    H    !    H    !    L    !
      !-----------!-------!---------!---------!---------!---------!
      !     D     !   D   !    L    !    H    !    L    !    H    !
      !-----------!-------!---------!---------!---------!---------!
      ! SET-RESET !   S   !    L    !    H    !    L    !    X    !
      !           !   R   !    X    !    L    !    H    !    L    !
      -------------------------------------------------------------

NOTE THAT A PAL16L8 MAY BE SUBSTITUTED FOR THIS DESIGN.  THEN THE CLOCK INPUT
(CLK) WOULD BE GATED WITH THE DATA INPUTS TO IMPLEMENT THE BASIC FLIP-FLOPS.

THE FUNCTION TABLE EXERCISES ALL INPUTS AND TESTS BASIC FUNCTION PERFORMANCE.
PALASM EXERCISES THE FUNCTION TABLE TO SIMULATE THE BASIC CLOCKED FLIP-FLOPS.