$DEBUG PAGELENGTH(55)

/*********************/
/*                   */
/*  E X $ O B J H E X*/
/*                   */
/*********************/

M$EX$OBJHEX: DO;

$NOLIST
$INCLUDE(COMMON.DCL)
$INCLUDE(ISIS.DCL)
$INCLUDE(:F1:ISISIO.DCL)
$LIST

GET$FNAME: PROCEDURE(NAME$P,TYPE,WILDCARD,NULLNAME,EXTPNT) EXTERNAL;
   DECLARE
       NAME$P ADDRESS,
       TYPE BYTE,
       WILDCARD BOOLEAN,
       NULLNAME BOOLEAN,
       EXTPNT BOOLEAN;
END GET$FNAME;

DECLARE MSG$FILL$IN(1) BYTE EXTERNAL;

$INCLUDE(STRING.DCL)

EX$OBJHEX: PROCEDURE (COM$LINE$P,COM$TYPE$P) PUBLIC;
   DECLARE
      COM$LINE$P ADDRESS,
      COM$TYPE$P ADDRESS;
   DECLARE
      (COM$LINE BASED COM$LINE$P) STRING,
      (COM$TYPE BASED COM$TYPE$P) BYTE;
   DECLARE
      NAME STRUCTURE(
         ML ADDRESS,
         L ADDRESS,
         D(15) BYTE
         );
   DECLARE
      COMP1 STRUCTURE(
         ML ADDRESS,
         L ADDRESS,
         D(8) BYTE
         ) DATA (7,7,'OBJHEX ',0);
   DECLARE
      COMP2 STRUCTURE(
         ML ADDRESS,
         L ADDRESS,
         D(5) BYTE
         ) DATA (4,4,' TO ',0);
   DECLARE
      COMP3 STRUCTURE(
         ML ADDRESS,
         L ADDRESS,
         D(3) BYTE
         ) DATA (2,2,CR,LF,0);
   DECLARE
      CONSOL$LINE$I ADDRESS;
      DECLARE I BYTE;
   DECLARE MSG1(*) BYTE DATA(
      LF,
      '  --- CONVERT OBJ FILE TO HEX --- ',CR,LF,
      '   OBJ FILE            HEX FILE',CR,LF,
      '..............      ..............',CR,
      0);
   DECLARE MSG2(*) BYTE DATA(
      C$RGT,C$RGT,C$RGT,C$RGT,
      C$RGT,C$RGT,C$RGT,C$RGT,
      C$RGT,C$RGT,C$RGT,C$RGT,
      C$RGT,C$RGT,C$RGT,C$RGT,
      C$RGT,C$RGT,C$RGT,C$RGT,
      0);
   CALL MSG$OUT(.MSG$FILL$IN);
   CALL MSG$OUT(.MSG1);
   COM$LINE.L=0;
   CALL APPEND$S(.COM$LINE,.COMP1);
   CALL GET$FNAME(.NAME,1,FALSE,FALSE,FALSE);
   CALL APPEND$S(.COM$LINE,.NAME);
   CALL APPEND$S(.COM$LINE,.COMP2);
   CALL MSG$OUT(.MSG2);
   CALL GET$FNAME(.NAME,3,FALSE,FALSE,FALSE);
   CALL APPEND$S(.COM$LINE,.NAME);
   CALL APPEND$S(.COM$LINE,.COMP3);
   CALL MSG$OUT(.(CLR$SCRN,0));
   COM$TYPE=1;

END EX$OBJHEX;

END M$EX$OBJHEX;