$DEBUG PAGEWIDTH(80) PAGELENGTH(55)

/*********************/
/*                   */
/*  E X E C U T E 1  */
/*                   */
/*********************/

M$EXECUTE1: DO;

$NOLIST
$INCLUDE(COMMON.DCL)
$INCLUDE(ISIS.DCL)
$INCLUDE(STRING.DCL)
$INCLUDE(:F1:ISISIO.DCL)
$LIST

/****************************************************/
/*                                                  */
/*  PROCEDURE NAME - EXECUTE1                       */
/*                                                  */
/*  FUNCTION - EXECUTE A PROGRAM, BY INSERTING A    */
/*              COMMAND INTO ISIS-II LINE BUFFER,   */
/*              LOADING THE PROGRAM, AND            */
/*              TRANSFERRING CONTROL.               */
/*                                                  */
/*                                                  */
/*  INPUT - COM$LINE$P : ADDRESS, A POINTER TO A    */
/*                        STRING CONTAINING THE     */
/*                        COMMAND LINE.             */
/*                                                  */
/*  OUTPUT - NONE.                                  */
/*                                                  */
/*  LAST UPDATED - 23.5.82   DROR                   */
/*                                                  */
/****************************************************/

DECLARE MSG$NOT$EXISTS(1) BYTE EXTERNAL;

EXECUTE1: PROCEDURE(COM$LINE$P) PUBLIC;

   DECLARE COM$LINE$P ADDRESS;
   DECLARE (COM$LINE BASED COM$LINE$P) STRING;
   DECLARE
      CI$BUFF(122) BYTE AT (3000H),  /* ISIS-II :CI: BUFFER */
      CI$I ADDRESS AT (307EH);       /* INDEX TO NEXT CHAR IN :CI: BUFFER */
   DECLARE
      I ADDRESS,
      STAT ADDRESS,
      ENTRY ADDRESS;

   I=0;
   DO WHILE((COM$LINE.D(I) <> ' ') AND (I<COM$LINE.L));
      I=I+1;
   END;
   CI$I=I;
   CALL MOVE(COM$LINE.L,.COM$LINE.D,.CI$BUFF);
   CALL MSG$OUT(.('-',0));
   CALL MSG$OUT(.COM$LINE.D);
   CALL LOAD(.COM$LINE.D,0,1,.ENTRY,.STAT);

   CALL ERROR$MSG(STAT);
   IF STAT=13
      THEN CALL MSG$OUT(.MSG$NOT$EXISTS);
   CALL EXIT;

END EXECUTE1;


END M$EXECUTE1;