;
;   *-*-*   FORM_TRK0.CSD   *-*-*
;
;   This Submit file formats only the second stage of the PC Bus
;   Bootstrap Loader on an iRMX hard disk and then installs the
;   iRMX III.1.3 Operating System files on it from tape.  Files from
;   a previous release will be renamed before the new directory
;   structure and files are installed.
;
;   Invocation:
;      submit :tape:form_trk0(device_name)
;
;   Where:  device_name is the physical device name of the device on
;               which you will be installing iRMX III.
;
;
attachdevice %0 as :w: delay
;
;   Format only track 0 of the hard disk.
;
format :w: s120boot bootstrap
;
;   Prepare for the installation by ensuring that the system manager
;   has complete access rights to the files that will be affected.
;
permit :w:,                   &
       :w:bsl,                &
       :w:msa32,              &
       :w:net,                &
       :w:rboot32,            &
       :w:rmx386,             &
       :w:sys386,             &
       :w:user,               &
       :w:boot32,             &
       :w:boot32/rmx   drau u=0

traverse :w:lang286 permit * drau u=0
traverse :w:util286 permit * drau u=0
traverse :w:util386 permit * drau u=0
traverse :w:inc permit * drau u=0
traverse :w:lib permit * drau u=0

;   Directories from a previous release must be renamed.  If any of these
;   directories exist, the current release of the iRMX III Operating System
;   has already been installed on your hard disk.  The next command will
;   prompt you to delete the directory if it exists at which point you
;   should exit this Submit file by typing a Control-C.  Refer to the
;   Software Installation Guide for information on how to deal with
;   this situation.

rename :w:boot32 over :w:boot32_old
rename :w:bsl over :w:bsl_old
rename :w:msa32 over :w:msa32_old
rename :w:net over :w:net_old
rename :w:rboot32 over :w:rboot32_old
rename :w:rmx386 over :w:rmx386_old
rename :w:sys386 over :w:sys386_old
rename :w:user over :w:user_old

attachdevice tape as t p

copy :sd:rmx386/config/cmd/stuffy

restore :t: over :w:

detachdevice :t:
;
;   If the VT product has been installed, copy its files back to :w:rmx386.
;   If the hard disk was formatted or the VT product has not been installed,
;   the copy will fail.
;
copy :w:rmx386_old/ios/xdrvt.lib to :w:rmx386/ios
copy :w:rmx386_old/vt/* to :w:rmx386/vt
;
;   Copy the third stage and the boot file from the boot diskette
;   to the hard disk.
;
copy :sd:r'?'s120thirdstg over :w:r'?'s120thirdstg
copy :sd:boot32/rmx over :w:boot32/rmx

permit :w:boot32, &
       :w:boot32/*   nr user=world

copy :sd:rmx386/config/rlogon over :w:user/world/prog/r'?'logon
copy :sd:user/super/prog/r'?'logoff over :w:user/world/prog/r'?'logoff
copy :sd:user/super/prog/alias.csd over :w:user/world/prog

copy :sd:rmx386/config/rlogon over :w:user/super/prog/r'?'logon
copy :sd:user/super/prog/r'?'logoff over :w:user/super/prog/r'?'logoff
copy :sd:user/super/prog/alias.csd over :w:user/super/prog

;
;   Copy the default configuration files.
;
copy :sd:rmx386/config/udf, &
     :sd:rmx386/config/cdf, &
     :sd:rmx386/config/terminals, &
     :sd:rmx386/config/logon.msg, &
     :sd:rmx386/config/alias.csd, &
     :sd:rmx386/config/termcap over :w:rmx386/config

copy :sd:rmx386/config/user/super, &
     :sd:rmx386/config/user/world over :w:rmx386/config/user
;
;   Duplicate the default configuration files.
;
copy :sd:rmx386/config/udf, &
     :sd:rmx386/config/cdf, &
     :sd:rmx386/config/user/super, &
     :sd:rmx386/config/user/world, &
     :sd:rmx386/config/logon.msg, &
     :sd:rmx386/config/rlogon, &
     :sd:rmx386/config/rinit, &
     :sd:rmx386/config/termcap, &
     :sd:user/super/prog/alias.csd over :w:rmx386/config/default
;
; Duplicate the third stage
;
copy :sd:r'?'s120thirdstg over :w:rmx386/config/default/rs120thirdstg

copy :sd:rmx386/config/cmd/tape/* over :w:rmx386/config/cmd/tape
copy :sd:rmx386/config/cmd/diskette/* over :w:rmx386/config/cmd/diskette

copy :sd:rmx386/config/cmd/tinstall.csd, &
     :sd:rmx386/config/cmd/instal.csd, &
     :sd:rmx386/config/cmd/stuffy, &
     :sd:rmx386/config/cmd/mkstdir.csd, &
     :sd:rmx386/config/cmd/mksys.csd over :w:rmx386/config/cmd

permit :w:user, :w:user/world, :w:user/world/prog, &
       :w:user/world/prog/r'?'logon, &
       :w:user/world/prog/r'?'logoff, &
       :w:user/world/prog/alias.csd drau u=world

permit :w:rmx386/config,            &
       :w:rmx386/config/*,          &
       :w:rmx386/config/default,    &
       :w:rmx386/config/default/*,  &
       :w:rmx386/config/user/*,     &
       :w:rmx386/config/cmd/*,      &
       :w:rmx386/config/cmd/tape/*, &
       :w:rmx386/config/cmd/diskette/* nr u=world

detachdevice :w:
;
;   The iRMX III.1.3 Operating System software is installed on the hard disk.
;   Directories from a previous release have been renamed to *_old.
;
;   Next the system device will be changed from the diskette to
;   the hard disk.
;
changesd %0